.vim/plugin/characterize.vim

   1 " characterize.vim - Unicode character metadata
   2 " Maintainer:   Tim Pope
   3 " Version:      1.0
   4
   5 if exists("g:loaded_characterize") || v:version < 700 || &cp
   6   finish
   7 endif
   8 let g:loaded_characterize = 1
   9
  10 function! s:info(char)
  11   if empty(a:char)
  12     return 'NUL'
  13   endif
  14   let charseq = a:char
  15   let outs = []
  16   while !empty(charseq)
  17     let nr = charseq ==# "\n" ? 0 : char2nr(charseq)
  18     let char = nr < 32 ? '^'.nr2char(64 + nr) : nr2char(nr)
  19     let charseq = strpart(charseq, nr ? len(nr2char(nr)) : 1)
  20     let out = '<' . (empty(outs) ? '' : ' ') . char . '> ' . nr
  21     if nr < 256
  22       let out .= printf(', \%03o', nr)
  23     endif
  24     let out .= printf(', U+%04X', nr)
  25     let out .= ' '.characterize#description(nr, '<unknown>')
  26     for digraph in characterize#digraphs(nr)
  27       let out .= ", \<C-K>".digraph
  28     endfor
  29     for emoji in characterize#emojis(nr)
  30       let out .= ', '.emoji
  31     endfor
  32     let entity = characterize#html_entity(nr)
  33     if !empty(entity)
  34       let out .= ', '.entity
  35     endif
  36     call add(outs, out)
  37   endwhile
  38   return join(outs, ' ')
  39 endfunction
  40
  41 nnoremap <silent><script> <Plug>(characterize) :<C-U>echo <SID>info(matchstr(getline('.')[col('.')-1:-1],'.'))<CR>
  42 if !hasmapto('<Plug>(characterize)', 'n')
  43   nmap ga <Plug>(characterize)
  44 endif
  45
  46 " vim:set sw=2 et: