.vimrc

   1 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
   2 " $Id$
   3 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
   4 " Multi-version vimrc compatible with version 4 and above.
   5 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
   6
   7 " Note that "if <condition> | call Something() | endif" syntax is unsupported
   8 " in Vim 4 so we write all our functions out the long way.  It does work in
   9 " autocommand definitions, however.
  10
  11 " Vim 4 complains if version isn't set in the configuration file.
  12 version 4.0
  13
  14 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
  15 " Handle options safe to use in version 4.  Vim 4 parses but ignores the
  16 " "if version" syntax used later in this file so we don't use it.  No attempt
  17 " is made to make this configuration compatible with Vim 3.
  18 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
  19 " No compatibility mode.
  20 se nocp
  21
  22 " Tabstop 2.
  23 se ts=2
  24 " And use spaces not tabs.
  25 se expandtab
  26 " And << and >> indent by 2.
  27 se sw=2
  28
  29 " Allow backspace to delete before start of line.
  30 se bs=2
  31
  32 " Show the ruler.
  33 se ruler
  34 " Show partial commands in the ruler.
  35 se showcmd
  36 " And always show the status line.
  37 se laststatus=2
  38
  39 " Use C indent style.
  40 se cindent
  41 se cinkeys=0{,0},0),:,!^F,o,O,e
  42 se cinoptions=b1,c2
  43
  44 " GUI options.
  45 se go=aglmr
  46
  47 " Don't be bugged by messages at the bottom of the screen.
  48 se shm=aot
  49
  50 " Find as you type.
  51 se incsearch
  52
  53 " Case-insensitive search.
  54 se ignorecase
  55 " But override by typing capitals.
  56 se smartcase
  57
  58 " Look for ctags in home directory first.
  59 se tags=~/.tags,./tags,tags
  60
  61 " Don't timeout waiting to interpet, eg, <ESC>OA as an escape code.
  62 se ttimeoutlen=100
  63
  64 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
  65 " Handle options only available in Vim 5 and above.
  66 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
  67 if version >= "500"
  68 version 5.0
  69
  70 " Tell Vim we use dark backgrounds in our terminals.
  71 if ! has("gui_running")
  72   se bg=dark
  73 endif
  74
  75 " Enable tab-completion prompting for commands.
  76 se wildmenu
  77 " Don't list object files when globbing files to load.
  78 se wildignore+=*.o,*.obj
  79 " So there's no need to assign them low priority.
  80 se suffixes-=*.o,*.obj
  81
  82 " Vim 5 hardcodes the size of numbers column to 8.
  83 let numberwidth=8
  84
  85 " Save sessions in UNIX format with / as file separator.  This is
  86 " cross-platform.
  87 se ssop+=unix,slash
  88
  89 " Nuke any pre-existing autocommands.
  90 autocmd!
  91
  92 " Save the current window width so we can restore it when we quit.
  93 let oldcols=&columns
  94
  95 " More GUI options.  Add icon, tearoffs and toolbar.
  96 se go+=itT
  97
  98 " Allow dynamic window resize even if we aren't in an xterm.
  99 se t_WS=\e[8;%p1%d;%p2%dt
 100
 101 " Highlight search results.
 102 se hlsearch
 103
 104 " Syntax highlighting.  New versions will use syn enable instead.
 105 if version < 600
 106   syn on
 107 endif
 108
 109 " Use a discernably different colour to highlight the cursor which shows
 110 " matching brackets.  Our regular cursor is green so use blue instead of cyan.
 111 hi MatchParen ctermbg=blue
 112
 113 " Catch typos.
 114 command! W :w
 115 command! Wq :wq
 116 command! Wqa :wqa
 117
 118 " Set up our variables.
 119 fun! Iain_Vars()
 120   if ! exists("b:iainlist")
 121     let b:iainlist = 0
 122   endif
 123   if ! exists("b:iainhex")
 124     let b:iainhex = 0
 125   endif
 126   if ! exists("b:iainverbose")
 127     let b:iainverbose = 0
 128   endif
 129   if ! exists("b:iainstatus")
 130     " Window Flags: (F)ocused, (I)nsert mode, Cursor (H)old.
 131     let b:iainstatus = "Fih"
 132   endif
 133 endfun
 134
 135 " Helper for status line.
 136 " Show space, underscore or dollar sign depending on list mode.
 137 fun! Show_List()
 138   call Iain_Vars()
 139   if b:iainlist == 0
 140     " No list.
 141     return " "
 142   elseif b:iainlist == 1
 143     " Just tabs.
 144     return "_"
 145   else
 146     " Full list.
 147     return "\$"
 148   endif
 149 endfun
 150
 151 " Helper for status line.
 152 " Show c or C to denote case-sensitivity.
 153 fun! Show_Case()
 154   if &ic
 155     return "c"
 156   else
 157     return "C"
 158   endif
 159 endfun
 160
 161 " Helper for status line.
 162 " Show the size of the tabstop.
 163 fun! Show_Tabstop()
 164   return &ts
 165 endfun
 166
 167 " Helper for status line.
 168 " Show p when paste mode is on.
 169 fun! Show_Paste()
 170   if &paste
 171     return "p"
 172   else
 173     return ""
 174   endif
 175 endfun
 176
 177 " Show the status line.
 178 fun! Show_StatusLine()
 179   call Iain_Vars()
 180   let sl1='%2n\:\ %<%f\ [%{Show_List()}%{Show_Case()}%{Show_Tabstop()}%{Show_Paste()}%Y%M%R]\ %='
 181   let sl3='L:%4.6l/%-4.6L\ C:%3.6c\ \|\ %P'
 182   let hexformat='%b'
 183   if b:iainhex
 184     let hexformat='0\x%02B'
 185   endif
 186   if b:iainverbose
 187     let sl2=hexformat . '\ \|\ P:%4.6o\ '
 188   else
 189     let sl2=''
 190   endif
 191   exec "set statusline=" . sl1 . sl2 . sl3
 192 endfun
 193
 194 " Toggle case-sensitivity.
 195 fun! Invert_Case()
 196   let &ic = ! &ic
 197 endfun
 198
 199 " Restore window size.
 200 au VimLeave * if exists("oldcols") | let &columns=oldcols | endif
 201
 202 " Map Makefile mode.
 203 au BufEnter * if &ft == "make" | call MakeMode_map() | endif
 204 au BufLeave * if &ft == "make" | call MakeMode_unmap() | endif
 205
 206 " Entering Make mode.
 207 fun! MakeMode_map()
 208   set list
 209   set noexpandtab
 210 endfun
 211
 212 " Leaving Make mode.
 213 fun! MakeMode_unmap()
 214   set nolist
 215   set expandtab
 216 endfun
 217
 218 " Show the status line for the first time.
 219 call Show_StatusLine()
 220
 221 " Function to create mappings with either a hardcoded \ or <Leader>.
 222 fun! Mapping(keysequence,mapping)
 223   if version >= "600"
 224     exec "map \\" . a:keysequence . " " . a:mapping
 225   else
 226     exec "map <Leader>" . a:keysequence . " " . a:mapping
 227   endif
 228 endfun
 229
 230 " Use - and = to create underlines.
 231 call Mapping("-", "yyp:s/./-/g<RETURN>:let @/=''<RETURN>:<RETURN>")
 232 call Mapping("=", "yyp:s/./=/g<RETURN>:let @/=''<RETURN>:<RETURN>")
 233
 234 " Change to ts=2 with \2.
 235 call Mapping("2", ":se ts=2<CR>:<CR>")
 236 " Change to ts=4 with \4.
 237 call Mapping("4", ":se ts=4<CR>:<CR>")
 238 " Change to ts=8 with \8.
 239 call Mapping("8", ":se ts=8<CR>:<CR>")
 240 " Change to ts=16 with \6.
 241 call Mapping("6", ":se ts=16<CR>:<CR>")
 242 " Change to ts=32 with \3.
 243 call Mapping("3", ":se ts=32<CR>:<CR>")
 244 " Toggle paste mode with \p.
 245 call Mapping("p", ":se paste!<CR>:<CR>")
 246 " Swap case-sensitivity with \c.
 247 call Mapping("c", ":call Invert_Case()<CR>:<CR>")
 248 " Change number mode with \n.
 249 call Mapping("n", ":se number!<CR>:<CR>")
 250 " Expand or shrink window size with \> and \<.  For use after toggling number.
 251 call Mapping(">", ":exe 'se columns+=' . numberwidth<CR>:<CR>")
 252 call Mapping("<", ":exe 'se columns-=' . numberwidth<CR>:<CR>")
 253 " Clear search pattern with \/.
 254 call Mapping("/", ":let @/=\"\"<CR>:<CR>")
 255
 256 " Forget the Ex mode mapping.
 257 map Q <NOP>
 258
 259 endif
 260
 261 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
 262 " Handle options only available in Vim 6 and above.
 263 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
 264 if version >= "600"
 265 version 6.0
 266
 267 " Remember quickfix state.
 268 let g:quickfixing=0
 269
 270 " Set indenting by filetype.
 271 filetype indent on
 272
 273 " Less intrusive syntax highlighting.
 274 syn enable
 275
 276 " Nice GUI colour.
 277 if has("gui_running")
 278   se guifont=DejaVu\ Sans\ Mono\ 10
 279   colo darkblue
 280 elseif &t_Co > 16
 281   colo iain
 282 endif
 283 if has("win32")
 284   se guifont=DejaVu_Sans_Mono:h10:cANSI
 285 endif
 286
 287 " Ignore whitespace when diffing.
 288 se diffopt=filler,iwhite
 289
 290 " Expand window when doing a vertical diff.
 291 if &diff
 292   let &columns = 164
 293 endif
 294
 295 " Numbers in blue.
 296 highlight LineNr term=underline cterm=bold guifg=blue ctermfg=blue
 297
 298 " Remember that we are opening the quickfix window.
 299 au BufWinEnter quickfix let g:quickfixing=1
 300 au BufUnload * if &ft == "qf" | let g:quickfixing=0 | endif
 301
 302 " Make * and # work the way you expect in visual mode.
 303 vnoremap * y/\V<C-R>=substitute(escape(@@,"/\\"),"\n","\\\\n","ge")<CR><CR>
 304 vnoremap # y?\V<C-R>=substitute(escape(@@,"?\\"),"\n","\\\\n","ge")<CR><CR>
 305
 306 " Change list mode.
 307 fun! Cycle_List()
 308   let basic='tab:\\_,trail:_,extends:<,precedes:>'
 309   call Iain_Vars()
 310   let b:iainlist = b:iainlist + 1
 311   if b:iainlist > 2
 312     let b:iainlist = 0
 313   endif
 314   if b:iainlist == 0
 315     set nolist
 316   elseif b:iainlist == 1
 317     exec "set lcs=" . basic
 318     set list
 319   else
 320     exec "set lcs=" . basic . ",eol:$"
 321     set list
 322   endif
 323 endfun
 324
 325 " Cycle between hex and decimal display of toolbar stuff.
 326 fun! Cycle_HexStatusLine()
 327   call Iain_Vars()
 328   let b:iainhex = ! b:iainhex
 329   call Show_StatusLine()
 330 endfun
 331
 332 " Cycle verbose display of toolbar stuff.
 333 fun! Cycle_VerboseStatusLine()
 334   call Iain_Vars()
 335   let b:iainverbose = ! b:iainverbose
 336   call Show_StatusLine()
 337 endfun
 338
 339 " Toggle quickfix window.
 340 fun! Cycle_Quickfix()
 341   if g:quickfixing == 1
 342     cclose
 343     let g:quickfixing=0
 344   else
 345     copen
 346   endif
 347 endfun
 348
 349 " Swap hex/decimal statusline with \x.
 350 call Mapping("x", ":call Cycle_HexStatusLine()<CR>:<CR>")
 351 " Change statusline verbosity with \v.
 352 call Mapping("v", ":call Cycle_VerboseStatusLine()<CR>:<CR>")
 353 " Cycle list styles with \l.
 354 call Mapping("l", ":call Cycle_List()<CR>:<CR>")
 355 " Toggle tags with \t.
 356 call Mapping("t", ":Tlist<CR>")
 357 " Change foldmethod with \f.
 358 call Mapping("f", ":se foldenable!<CR>:<CR>")
 359 " Toggle quickfix window with \q.
 360 call Mapping("q", ":call Cycle_Quickfix()<CR>:<CR>")
 361 " Rerun filetype detection with \s.  The s is for syntax, as this will be
 362 " updated as a side-effect.
 363 call Mapping("s", ":filetype detect<CR>:<CR>")
 364
 365 " Change status bar colour when various things happen.
 366 fun! Highlight_StatusLine(flag)
 367   " Get current status.
 368   call Iain_Vars()
 369
 370   " Change the status based on the flag.  XXX: Does Vim let us to do flags?
 371   let re = "[" . tolower(a:flag) . toupper(a:flag) . "]"
 372   let b:iainstatus = substitute(b:iainstatus, re, a:flag, "")
 373
 374   " Default colour.
 375   let s:colour = "darkblue"
 376   let s:termcolour = ""
 377   let s:term88colour = "17"
 378   let s:term256colour = "17"
 379   " Maybe override depending on status.
 380   if b:iainstatus =~# "H"
 381     if b:iainstatus =~# "I"
 382       " Held in insert mode.  Add extra highlight if we don't have focus.
 383       if b:iainstatus =~# "f"
 384         let s:colour = "darkmagenta"
 385       else
 386         let s:colour = "darkred"
 387       endif
 388       let s:term88colour = "32"
 389       let s:term256colour = "88"
 390     endif
 391   else
 392     if b:iainstatus =~# "I"
 393       " Regular insert mode.
 394       let s:colour = "darkred"
 395       let s:term88colour = "32"
 396       let s:term256colour = "88"
 397     endif
 398   endif
 399
 400   if &t_Co == 88
 401     let s:termcolour = s:term88colour
 402   elseif &t_Co == 256
 403     let s:termcolour = s:term256colour
 404   else
 405     let s:termcolour = s:colour
 406   endif
 407
 408   exec "highlight StatusLine guifg=white guibg=" . s:colour . " ctermbg=white ctermfg=" . s:termcolour
 409 endfun
 410
 411 call Highlight_StatusLine("")
 412 endif
 413
 414 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
 415 " Handle options only available in Vim 7 and above.
 416 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
 417 if version >= "700"
 418 version 7.0
 419
 420 au CursorHoldI * call Highlight_StatusLine("H")
 421 au CursorMovedI * call Highlight_StatusLine("h")
 422 au FocusGained * call Highlight_StatusLine("F")
 423 au FocusLost * call Highlight_StatusLine("f")
 424 au InsertEnter * call Highlight_StatusLine("I")
 425 au InsertLeave * call Highlight_StatusLine("i")
 426
 427 " Make diffs vertical by default.
 428 se diffopt+=vertical
 429
 430 " Set size of numbers column.
 431 se numberwidth=5
 432
 433 " Add "previous tab" mapping as gb.
 434 map gb :tabPrev<CR>
 435 endif