+
+" Look for ctags in home directory first.
+se tags=~/.tags,./tags,tags
+
+" Don't timeout waiting to interpet, eg, <ESC>OA as an escape code.
+se ttimeoutlen=100
+
+" Use ^B to search backward when completing.
+inoremap <C-b> <C-p>
+" Use ^L to show matching completions but don't select one.
+inoremap <C-l> <C-n><C-p>
+
+" Swap jump keys.
+noremap ' `
+noremap ` '
+"}}}1
+
+" Find stuff.
+if (has("win32") || has("win64")) && version >= "504"
+ se rtp=~/.vim,$VIMRUNTIME
+endif
+
+""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
+" Handle options only available in Vim 5 and above.
+""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
+if version >= "500" "{{{1
+version 5.0
+
+" Tell Vim we use dark backgrounds in our terminals.
+if ! has("gui_running")
+ se bg=dark
+endif
+
+" Allow mouse use in a terminal but only if it can work.
+if has("xterm_clipboard")
+ se mouse=nvir
+endif
+
+" Update more quickly. For use with sign highlighting as polling for
+" CursorMove makes redrawing slow.
+if has("signs")
+ se updatetime=500
+endif
+
+" Enable tab-completion prompting for commands.
+if has("wildmenu")
+ se wildmenu
+ " Don't list object files when globbing files to load.
+ se wildignore+=*.o,*.obj
+ " So there's no need to assign them low priority.
+ se suffixes-=*.o,*.obj
+endif
+
+" Save sessions in UNIX format with / as file separator. This is
+" cross-platform.
+if has("mksession")
+ se ssop+=unix,slash
+endif
+
+" How often do we need to use ^A/^X on octals?
+se nf=hex
+
+" Nuke any pre-existing autocommands.
+if has("autocmd")
+ augroup Display
+ autocmd!
+ augroup Mode
+ autocmd!
+ if has("signs")
+ augroup Signs
+ autocmd!
+ endif
+ augroup StatusLine
+ autocmd!
+ augroup File
+ autocmd!
+ augroup END
+endif
+
+" Save the current window dimensions so we can restore them when we quit.
+if ! exists("g:oldcols")
+ let g:oldcols=&columns
+endif
+if ! exists("g:oldlines")
+ let g:oldlines=&lines
+endif
+
+" More GUI options. Add icon and tearoffs.
+if has("gui")
+ se go+=i
+ se go+=t
+endif
+
+" Allow dynamic window resize even if we aren't in an xterm.
+se t_WS=\e[8;%p1%d;%p2%dt
+
+" Highlight search results.
+if has("extra_search")
+ se hlsearch
+endif
+
+" Syntax highlighting. New versions will use syn enable instead.
+if version < "600"
+ syn on
+endif
+
+if has("user_commands")
+ " Catch typos.
+ command! W :w
+ command! Wq :wq
+ command! Wqa :wqa
+endif
+
+" Forget the Ex mode mapping.
+map Q <NOP>
+
+if has("autocmd")
+ " Position the compview plugin window.
+ au Display BufEnter -SearchResults- set buftype=nowrite | set nonumber | wincmd J
+endif
+endif "}}}1
+
+""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
+" Handle options only available in Vim 5.2 and above.
+""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
+if version >= "502" "{{{1
+version 5.2
+
+" Helper to initialise a variable.
+fun! Prep_Var(var, value) "{{{2
+ if exists(a:var)
+ return
+ endif
+ exe "let " . a:var . "=" . a:value
+endfun "}}}2
+
+" Set up our variables.
+fun! Iain_Vars() "{{{2
+ call Prep_Var("w:iainlist", 0)
+ call Prep_Var("b:iainhex", 0)
+ call Prep_Var("b:iainverbose", 0)
+ " Window Flags: (F)ocused, (I)nsert mode, Cursor (H)old.
+ call Prep_Var("b:iainstatus", "'Fih'")
+ call Prep_Var("g:iainextracolumnsnumber", "''")
+ call Prep_Var("g:iainextracolumnslist", "''")
+ call Prep_Var("b:iaincul", 0)
+ call Prep_Var("b:iainalt", 0)
+ if has("signs")
+ call Prep_Var("g:marksigns", 0)
+ call Prep_Var("g:firstsign", 100)
+ endif
+ call Prep_Var("g:resizable", "''")
+endfun "}}}2
+
+" Show the window title.
+fun! Show_TitleString() "{{{2
+ if bufname("") == ""
+ let l:ts1='Vim'
+ else
+ " Vim 5 doesn't have printf.
+ let l:ts1=bufnr("")
+ if l:ts1 < 10
+ let l:ts1=" " . l:ts1
+ endif
+ let l:ts1=l:ts1 . ": " . expand('%t')
+ endif
+ let l:ts1=l:ts1 . " (" . getcwd() . ")"
+ if has("clientserver")
+ let l:ts1=l:ts1 . " " . v:servername
+ endif
+ return l:ts1
+endfun "}}}2
+
+" Toggle case-sensitivity.
+fun! Invert_Case() "{{{2
+ let &ic = ! &ic
+endfun "}}}2
+
+" Can we resize this window?
+fun! Can_Resize() "{{{2
+ call Iain_Vars()
+
+ if g:resizable == "0" || g:resizable == "1"
+ return g:resizable
+ endif
+
+ " Do we KNOW we can(not) resize?
+ if has("gui_running")
+ let g:resizable = 1
+ elseif $RESIZABLE == &term
+ let g:resizable = 1
+ elseif $RESIZABLE == "0"
+ let g:resizable = 0
+ else
+ " Assume we can. Allow overriding.
+ let g:resizable = 1
+ endif
+ return g:resizable
+endfun "}}}2
+
+" Grow or shrink the window width.
+fun! Resize_Columns(op, ...) "{{{2
+ if a:op == ""
+ return
+ endif
+
+ if ! Can_Resize()
+ return
+ endif
+
+ if a:0 == 0
+ " Vim 5 hardcodes the size of numbers column to 8.
+ if version >= "700" && has("linebreak")
+ let l:columns = &numberwidth
+ else
+ let l:columns = 8
+ endif
+ else
+ let l:columns = a:1
+ endif
+
+ exe "let l:resize=" . &columns . a:op . l:columns
+ let l:resize = "se columns=" . l:resize
+
+ " HACK: Inside screen there is an extra line for the status bar. Vim
+ " manages the resize by sending an escape sequence to set the number of
+ " lines and number of columns in one action. To do this it will first query
+ " the number of lines and then set <same number of lines> by <new number of
+ " columns>. Because of the extra line for the status bar this results in
+ " the real terminal being shrunk by a line. We ask for the terminal to grow
+ " by a line so it ends up actually being the same.
+ if &term =~ '^screen'
+ let l:resize = l:resize . " lines=" . (&lines + 1)
+ endif
+
+ exe l:resize
+endfun "}}}2
+
+" Grow or shrink the window height.
+fun! Resize_Lines(op, lines) "{{{2
+ if a:op == ""
+ return
+ endif
+
+ if ! Can_Resize()
+ return
+ endif
+
+ exe "let l:resize=" . &lines . a:op . a:lines
+ if &term =~ '^screen'
+ let l:resize = l:resize + 1
+ endif
+ let l:resize = "se lines=" . l:resize
+
+ exe l:resize
+endfun "}}}2
+
+" Set extra columns depending on window status.
+fun! Extra_Columns(extra, var, ...) "{{{2
+ " Vim 6 doesn't have winnr("$"). Determine which windows are open
+ " ourselves by using :windo to incremement a counter. As Vim 5
+ " doesn't have :windo we require Vim 6 for this.
+ if v:version < "600"
+ return ""
+ endif
+ if ! has("windows")
+ return ""
+ endif
+
+ " Remember which window we're in.
+ let l:winnr = winnr()
+ let l:num_windows = 0
+ windo let l:num_windows = l:num_windows + 1
+ " Switch back to the window we were in.
+ exe l:winnr . "wincmd w"
+
+ call Iain_Vars()
+
+ if a:0 == 0
+ let l:condition = ""
+ else
+ let l:condition = a:1
+ endif
+
+ let l:n = 0
+ let l:i = 1
+ let l:windows = ""
+ while l:n < l:num_windows
+ " If window w exists then getwinvar(w, "&modified") will be 0 or 1.
+ if getwinvar(l:i, "&modified") =~ '^\d'
+ let l:n = l:n + 1
+
+ let l:val = 0
+ exe "if getwinvar(" . l:i . ", '" . a:var . "') " . l:condition . " | let l:val = 1 | endif"
+ if l:val
+ exe "let l:windows = '" . l:windows . ":" . l:i . "'"
+ endif
+ endif
+ let l:i = l:i + 1
+ endwhile
+
+ let l:extra = "g:iainextracolumns" . a:extra
+ exe "let l:val = " . l:extra
+ exe "let " . l:extra . " = '" . l:windows . "'"
+
+ if l:windows == l:val
+ return ""
+ endif
+
+ if l:windows == ""
+ return "-"
+ elseif l:val == ""
+ return "+"
+ endif
+endfun "}}}2
+
+" Toggle number display.
+fun! Number(resize) "{{{2
+ call Iain_Vars()
+ let &number = ! &number
+
+ " Ensure we keep track of any extra columns even if we aren't resizing.
+ " This prevents confusion when number is set at startup.
+ let l:extra = Extra_Columns("number", "&number")
+
+ if a:resize
+ call Resize_Columns(l:extra)
+ endif
+endfun "}}}2
+
+" Restore window size.
+if has("autocmd") && ! has("gui_running")
+ au Display VimLeave * if exists("g:oldcols") | call Resize_Columns("-", (&columns - g:oldcols)) | endif
+ au Display VimLeave * if exists("g:oldlines") | call Resize_Lines("-", (&lines - g:oldlines)) | endif
+endif
+
+" Map Makefile mode.
+if has("autocmd")
+ au Mode BufEnter * if &ft == "make" | call MakeMode_map() | endif
+ au Mode BufLeave * if &ft == "make" | call MakeMode_unmap() | endif
+endif
+
+" Entering Make mode.
+fun! MakeMode_map() "{{{2
+ call Iain_Vars()
+ let w:iainlist=1
+ call Cycle_List()
+ set ts=8
+ set noexpandtab
+endfun "}}}2
+
+" Leaving Make mode.
+fun! MakeMode_unmap() "{{{2
+ call Cycle_List()
+ set ts=2
+ set expandtab
+endfun "}}}2
+
+" Function to create mappings with either a hardcoded \ or <Leader>.
+fun! Mapping(keysequence,mapping) "{{{2
+ if version < "600"
+ exec "map \\" . a:keysequence . " " . a:mapping
+ else
+ exec "map <Leader>" . a:keysequence . " " . a:mapping
+ endif
+endfun "}}}2
+
+" Use - and = to create underlines.
+call Mapping("-", "yyp:s/./-/g<RETURN>:let @/=''<RETURN>:<RETURN>")
+call Mapping("=", "yyp:s/./=/g<RETURN>:let @/=''<RETURN>:<RETURN>")
+
+" Change to ts=2 with \2.
+call Mapping("2", ":se ts=2<CR>:<CR>")
+" Change to ts=4 with \4.
+call Mapping("4", ":se ts=4<CR>:<CR>")
+" Change to ts=8 with \8.
+call Mapping("8", ":se ts=8<CR>:<CR>")
+" Change to ts=16 with \6.
+call Mapping("6", ":se ts=16<CR>:<CR>")
+" Change to ts=32 with \3.
+call Mapping("3", ":se ts=32<CR>:<CR>")
+" Toggle paste mode with \p.
+call Mapping("p", ":se paste!<CR>:<CR>")
+" Swap case-sensitivity with \c.
+call Mapping("C", ":call Invert_Case()<CR>:<CR>")
+" Change number mode with \n.
+call Mapping("n", ":call Number(1)<CR>:<CR>")
+" Expand or shrink window size with \> and \<.
+call Mapping(">", ":call Resize_Columns('+')<CR>:<CR>")
+call Mapping("<", ":call Resize_Columns('-')<CR>:<CR>")
+" Clear search pattern with \/.
+call Mapping("/", ":let @/=\"\"<CR>:<CR>")
+" Toggle alternate buffer name with \#.
+call Mapping("#", ":call Cycle_Alt()<CR>:<CR>")
+
+" Set graphical window title.
+if has("win32") || has("win64")
+ " Windows taskbar entries are probably too small to show full titles.
+ se titlestring=%t
+else
+ se titlestring=%{Show_TitleString()}
+endif
+
+" Vim tip 99: What's the highlighting group under the cursor?
+call Mapping("h", ":echo \"hi<\" . synIDattr(synID(line(\".\"),col(\".\"),1),\"name\") . '> trans<' . synIDattr(synID(line(\".\"),col(\".\"),0),\"name\") . \"> lo<\" . synIDattr(synIDtrans(synID(line(\".\"),col(\".\"),1)),\"name\") . \">\"<CR>")
+
+fun! Uncluttered_Buffer() "{{{2
+ if exists("uncluttered_buffer")
+ if uncluttered_buffer == 1
+ return 1
+ endif
+ endif
+
+ if version >= "600"
+ if &buftype != ''
+ return 1
+ endif
+ endif
+
+ if &ft == 'perforce'
+ return 1
+ endif
+
+ if &ft == 'svn'
+ return 1
+ endif
+
+ if &ft == 'gitcommit'
+ return 1
+ endif
+
+ return 0
+endfun "}}}2
+
+fun! Startup_Resize() "{{{2
+ let l:columns = 0
+
+ " Resize for numbers.
+ if &number
+ if version >= "700" && has("linebreak")
+ let l:columns = &numberwidth
+ else
+ let l:columns = 8
+ endif
+ endif
+
+ " Resize for signs.
+ if has("signs")
+ if g:marksigns
+ if version >= "600"
+ let l:columns = l:columns + 2
+ endif
+ endif
+ endif
+
+ if g:oldcols < (80 + l:columns)
+ call Resize_Columns("+", l:columns)
+ endif
+endfun "}}}2
+
+" Change status bar colour when various things happen.
+" Flags: H/h: Cursor held/moved.
+" F/f: Focus gained/lost.
+" I/i: Insert mode entered/left.
+fun! Highlight_StatusLine(flag) "{{{2
+ if ! has("statusline")
+ return
+ endif
+ " Get current status.
+ call Iain_Vars()
+
+ " Change the status based on the flag. XXX: Does Vim let us to do flags?
+ let l:ic = &ic
+ set ic
+ let b:iainstatus = substitute(b:iainstatus, a:flag, a:flag, "")
+ let &ic = l:ic
+
+ let l:normalcolour = "darkblue"
+ let l:editingcolour = "darkmagenta"
+ let l:warningcolour = "darkred"
+ let l:readonlycolour = "red"
+
+ " Default colour.
+ let l:colour = l:normalcolour
+ " Maybe override depending on status.
+ if b:iainstatus =~# "H"
+ if b:iainstatus =~# "I"
+ " Held in insert mode. Add extra highlight if we don't have focus.
+ if b:iainstatus =~# "f"
+ let l:colour = l:warningcolour
+ else
+ let l:colour = l:editingcolour
+ endif
+ endif
+ else
+ if b:iainstatus =~# "I"
+ " Regular insert mode.
+ let l:colour = l:editingcolour
+ endif
+ endif
+
+ " Override again if readonly.
+ if l:colour != l:normalcolour
+ if getbufvar("", "&ro")
+ let l:colour = l:readonlycolour
+ endif
+ endif
+
+ let l:termcolour = Iain_Colour(l:colour)
+
+ exec "highlight StatusLine gui=none term=none cterm=none guifg=white guibg=" . l:colour . " ctermfg=white ctermbg=" . l:termcolour
+ exec "highlight User1 gui=bold term=bold cterm=bold guifg=white guibg=" . l:colour . " ctermfg=white ctermbg=" . l:termcolour
+endfun "}}}2
+
+fun! Iain_Colour(colour) "{{{2
+ if &t_Co == 88
+ if a:colour == "darkblue"
+ return 17
+ elseif a:colour == "darkmagenta"
+ return 33
+ elseif a:colour == "darkred"
+ return 32
+ elseif a:colour == "red"
+ return 64
+ endif
+ elseif &t_Co == 256
+ if a:colour == "darkblue"
+ return 17
+ elseif a:colour == "darkmagenta"
+ return 90
+ elseif a:colour == "darkred"
+ return 88
+ elseif a:colour == "red"
+ return 196
+ endif
+ else
+ return a:colour
+ endif
+endfun "}}}2
+
+if has("autocmd")
+ au StatusLine VimEnter * call Highlight_StatusLine("")
+
+ " Show numbers by default.
+ au Display VimEnter * if ! Uncluttered_Buffer() | call Number(0) | endif
+endif
+endif "}}}1
+
+""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
+" Handle options only available in Vim 5.4 and above.
+""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
+if version >= "504" "{{{1
+version 5.4
+
+" Do we have Unicode?
+fun! Has_Unicode() "{{{2
+ if ! has('multi_byte')
+ return 0
+ endif
+
+ if version < "602"
+ return 0
+ endif
+
+ if &tenc =~? '^u\(tf\|cs\)'
+ return 1
+ endif
+
+ if ! strlen(&tenc) && &enc =~? '^u\(tf\|cs\)'
+ return 1
+ endif
+
+ return 0
+endfun "}}}2
+
+" Helper for status line.
+" Show space, underscore or dollar sign depending on list mode.
+fun! Show_List() "{{{2
+ call Iain_Vars()
+ if w:iainlist == 0
+ " No list.
+ return " "
+ elseif Has_Unicode()
+ if w:iainlist == 1
+ " Just tabs.
+ return "»"
+ else
+ " Full list.
+ return "¶"
+ endif
+ else
+ if w:iainlist == 1
+ return "_"
+ else
+ return "\$"
+ endif
+ endif
+endfun "}}}2
+
+" Helper for status line.
+" Show c or C to denote case-sensitivity.
+fun! Show_Case() "{{{2
+ if &ic
+ return "c"
+ else
+ return "C"
+ endif
+endfun "}}}2
+
+" Helper for status line.
+" Show the size of the tabstop.
+fun! Show_Tabstop() "{{{2
+ return &ts
+endfun "}}}2
+
+" Helper for status line.
+" Show p when paste mode is on.
+fun! Show_Paste() "{{{2
+ if &paste
+ return "p"
+ else
+ return ""
+ endif
+endfun "}}}2
+
+" Helper for status line.
+" Show v when virtualedit mode is block, insert or onemore.
+" Show V when virtualedit mode is all.
+fun! Show_VirtualEdit() "{{{2
+ if ! has("virtualedit")
+ return ""
+ endif
+
+ if &ve == "all"
+ return "V"
+ elseif &ve
+ return "v"
+ else
+ return ""
+ endif
+endfun "}}}2
+
+" Helper for status line.
+" Show U when persistent undo is on.
+" Show u when persistent undo is off but an undofile exists.
+fun! Show_Undo() "{{{2
+ if ! exists("&undofile")
+ return ""
+ endif
+
+ if &undofile
+ return "U"
+ elseif filereadable(undofile(expand("%")))
+ return "u"
+ else
+ return ""
+ endif
+endfun "}}}2
+
+" Helper for status line.
+" Show alternate buffer number and name.
+fun! Show_Alt() "{{{2
+ let l:alt = bufnr("#")
+ if l:alt < 0 || l:alt == bufnr("") || ! b:iainalt
+ return ""
+ endif
+
+ return " " . l:alt . ": " . expand("#:t")
+endfun "}}}2
+
+" Helper for status line.
+" Show scrollbind or cursorbind.
+fun! Show_Bind() "{{{2
+ if has("cursorbind")
+ if &cursorbind
+ if Has_Unicode()
+ return "⇄"
+ else
+ return ">"
+ endif
+ elseif &scrollbind
+ if Has_Unicode()
+ return "⇅"
+ else
+ return "^"
+ endif
+ endif
+ endif
+ return ""
+endfun "}}}2
+
+" Show the status line.
+fun! Show_StatusLine() "{{{2
+ if ! has("statusline")
+ return
+ endif
+ call Iain_Vars()
+ let l:sl1='%2n\:\ %<%1*%f%0*\ [%{Show_List()}%{Show_Bind()}%{Show_Case()}%{Show_Tabstop()}%{Show_Paste()}%{Show_VirtualEdit()}%{Show_Undo()}%Y%M%R]%{Show_Alt()}\ '
+ let l:sl3='L:%1*%4.6l%0*/%-4.6L\ C:%1*%3.6c%0*\ \|\ %P'
+ let l:hexformat='%b'
+ if b:iainhex
+ let l:hexformat='0\x%02B'
+ endif
+ if b:iainverbose
+ let l:sl1=l:sl1 . v:version . '\ %='
+ let l:sl2=l:hexformat . '\ \|\ P:%4.6o\ '
+ else
+ let l:sl1=l:sl1 . '%='
+ let l:sl2=''
+ endif
+ exec "set statusline=" . l:sl1 . l:sl2 . l:sl3
+endfun "}}}2
+
+" Show the status line for the first time.
+call Show_StatusLine()
+endif "}}}1
+
+""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
+" Handle options only available in Vim 6 and above.
+""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
+if version >= "600" "{{{1
+version 6.0
+
+if has("gui_win32")
+ se encoding=utf-8
+endif
+
+" Remember quickfix state.
+if has("quickfix")
+ let g:quickfixing=0
+endif
+
+" Set indenting by filetype.
+filetype indent on
+
+" Less intrusive syntax highlighting.
+if has("syntax")
+ syn enable
+endif
+
+" Set colours.