""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" $Id$
""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""

" Note that "if <condition> | call Something() | endif" syntax is unsupported 
" in Vim 4 so we write all our functions out the long way.  It does work in 
" autocommand definitions, however.

" Vim 4 complains if version isn't set in the configuration file.
version 4.0

""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" Handle options safe to use in version 4.  Vim 4 parses but ignores the 
" "if version" syntax used later in this file so we don't use it.  No attempt 
" is made to make this configuration compatible with Vim 3.
""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" No compatibility mode.
se nocp

" Tabstop 2.
se ts=2
" And use spaces not tabs.
se expandtab
" And << and >> indent by 2.
se sw=2

" Allow backspace to delete before start of line.
se bs=2

" Show the ruler.
se ruler
" Show partial commands in the ruler.
se showcmd
" And always show the status line.
se laststatus=2

" Use C indent style.
se cindent
se cinkeys=0{,0},0),:,!^F,o,O,e

" GUI options.
se go=aglmr

" Don't be bugged by messages at the bottom of the screen.
se shm=aot

" Find as you type.
se incsearch

" Case-insensitive search.
se ignorecase
" But override by typing capitals.
se smartcase

" Look for ctags in home directory first.
se tags=~/.tags,./tags,tags

" Use - and = to create underlines.
map - yyp:s/./-/g<RETURN>:let @/=''<RETURN>:<RETURN>
map = yyp:s/./=/g<RETURN>:let @/=''<RETURN>:<RETURN>

""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" Handle options only available in Vim 5 and above.
""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
if version >= "500"
version 5.0

" Nuke any pre-existing autocommands.
autocmd!

" Save the current window width so we can restore it when we quit.
let oldcols=&columns

" More GUI options.  Add icon, tearoffs and toolbar.
se go=agilmrtT

" Allow dynamic window resize even if we aren't in an xterm.
se t_WS=[8;%p1%d;%p2%dt

" Highlight search results.
se hlsearch

" Syntax highlighting.
syn on

" Catch typos.
command! W :w
command! Wq :wq
command! Wqa :wqa

" Set up our variables.
fun! Iain_Vars()
  if ! exists("b:iainlist")
    let b:iainlist = 0
  endif
  if ! exists("b:iainhex")
    let b:iainhex = 0
  endif
endfun

" Helper for status line.
" Show space, underscore or dollar sign depending on list mode.
fun! Show_List()
  call Iain_Vars()
  if b:iainlist == 0
    " No list.
    return " "
  elseif b:iainlist == 1
    " Just tabs.
    return "_"
  else
    " Full list.
    return "\$"
  endif
endfun

" Helper for status line.
" Show c or C to denote case-sensitivity.
fun! Show_Case()
  if &ic
    return "c"
  else
    return "C"
  endif
endfun

" Helper for status line.
" Show the size of the tabstop.
fun! Show_Tabstop()
  return &ts
endfun

" Helper for status line.
" Show p when paste mode is on.
fun! Show_Paste()
  if &paste
    return "p"
  else
    return ""
  endif
endfun

" Show the status line.
fun! Show_StatusLine()
  call Iain_Vars()
  let sl1='%2n\:\ %<%f\ [%{Show_List()}%{Show_Case()}%{Show_Tabstop()}%{Show_Paste()}%Y%M%R]\ %='
  let sl2='\ \|\ P:%4.6o\ L:%4.6l/%-4.6L\ C:%3.6c\ \|\ %P'
  let hexformat='%b'
  if b:iainhex
    let hexformat='0\x%02B'
  endif
  exec "set statusline=" . sl1 . hexformat . sl2
endfun

" Restore window size.
au VimLeave * if exists("oldcols") | let &columns=oldcols | endif

" Map C mode.
au BufEnter * if &ft == "c" || &ft == "cpp" | call CMode_map() | endif
au BufLeave * if &ft == "c" || &ft == "cpp" | call CMode_unmap() | endif

" Map Perl mode.
au BufEnter * if &ft == "perl" | call PerlMode_map() | endif
au BufLeave * if &ft == "perl" | call PerlMode_unmap() | endif

" Map Makefile mode.
au BufEnter * if &ft == "make" | call MakeMode_map() | endif
au BufLeave * if &ft == "make" | call MakeMode_unmap() | endif

" Entering C mode.
fun! CMode_map()
  let oldcinkeys=&cinkeys
  let oldcinwords=&cinwords
  set cinkeys=0{,0},:,0#,!^F,o,O,e
  set cinwords=if,else,while,do,for,switch
endfun

" Leaving C mode.
fun! CMode_unmap()
  set cinkeys=oldcinkeys
  set cinwords=oldcinwords
endfun

" Entering Perl mode.
fun! PerlMode_map()
  let oldcinkeys=&cinkeys
  let oldcinwords=&cinwords
  set cinkeys=0{,0},:,!^F,o,O,e
  set cinwords=if,else,while,do,for,eval
endfun

" Leaving Perl mode.
fun! PerlMode_unmap()
  set cinkeys=oldcinkeys
  set cinwords=oldcinwords
endfun

" Entering Make mode.
fun! MakeMode_map()
  set list
  set noexpandtab
endfun

" Leaving Make mode.
fun! MakeMode_unmap()
  set nolist
  set expandtab
endfun

" Show the status line for the first time.
call Show_StatusLine()
endif

""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" Handle options only available in Vim 6 and above.
""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
if version >= "600"
version 6.0

" Less intrusive syntax highlighting.
syn enable

" Nice GUI colour.
if has("gui_running")
  se guifont=Bitstream\ Vera\ Sans\ Mono\ 12
  colo darkblue
endif
if has("win32")
  se guifont=Bitstream_Vera_Sans_Mono:h10:cANSI
endif

" Expand window when doing a vertical diff.
if &diff
  let &columns = 164
endif

" Status bar matches the colour.
highlight StatusLine guifg=white guibg=blue ctermbg=white ctermfg=blue

" Make * and # work the way you expect in visual mode.
vnoremap * y/\V<C-R>=substitute(escape(@@,"/\\"),"\n","\\\\n","ge")<CR><CR>
vnoremap # y?\V<C-R>=substitute(escape(@@,"?\\"),"\n","\\\\n","ge")<CR><CR>

" Change list mode.
fun! Cycle_List()
  let basic='tab:\\_,trail:_,extends:<,precedes:>'
  call Iain_Vars()
  let b:iainlist = b:iainlist + 1
  if b:iainlist > 2
    let b:iainlist = 0
  endif
  if b:iainlist == 0
    set nolist
  elseif b:iainlist == 1
    exec "set lcs=" . basic
    set list
  else
    exec "set lcs=" . basic . ",eol:$"
    set list
  endif
endfun

" Cycle between hex and decimal display of toolbar stuff.
fun! Cycle_HexStatusLine()
  call Iain_Vars()
  let b:iainhex = ! b:iainhex
  call Show_StatusLine()
endfun

fun! Cycle_Number()
  if &number
    " Restore width.
    if &t_WS =~ '^.'
      let &columns=g:numbercols
    endif
    set nonumber
  else
    " Save width between number toggling.
    if &t_WS =~ '^'
      let g:numbercols=&columns
      let &columns=&columns+5
    endif
    set number
  endif
endfun

fun! Invert_Case()
  let &ic = ! &ic
endfun
" We'll use Q for various commands.  Unmap it.
map Q <Nop>

" Change to ts=2 with Q2.
map Q2 :se ts=2<CR>:<CR>
" Change to ts=4 with Q4.
map Q4 :se ts=4<CR>:<CR>
" Change to ts=8 with Q8.
map Q8 :se ts=8<CR>:<CR>
" Change to ts=16 with Q6.
map Q6 :se ts=16<CR>:<CR>
" Change to ts=32 with Q3.
map Q3 :se ts=32<CR>:<CR>
" Change foldmethod with Qf.
map Qf :se foldenable!<CR>:<CR>
" Toggle paste mode with Qp.
map Qp :se paste!<CR>:<CR>
" Swap hex/decimal statusline with Qx
map Qx :call Cycle_HexStatusLine()<CR>:<CR>
" Swap case-sensitivity with Qc.
map Qc :call Invert_Case()<CR>:<CR>
" Cycle list styles with Ql.
map Ql :call Cycle_List()<CR>:<CR>
" Change number mode with Qn.
map Qn :call Cycle_Number()<CR>:<CR>
" Toggle tags with Qt.
map Qt :Tlist<CR>

" Leaving Perl mode.
fun! PerlMode_unmap()
  set cinkeys=oldcinkeys
  set cinwords=oldcinwords
  set foldmethod=manual
endfun
endif

""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" Handle options only available in Vim 7 and above.
""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
if version >= "700"
version 7.0

" Add "previous tab" mapping as gb.
map gb :tabPrev<CR>
endif