" Define the function we'll use.  It's easier to do this than to faff about 
" trying to run a sequence of normal mode commands.
fun! SVNcommit()
  " Allow closing an unmodified spec.
  set nomod

  " Get the modified files.  Discount new files.
  let l:files = system("sed -n '1,/^$/d;/^[MR]..../{s//\"/;s/$/\"/p;}' " . bufname(""))

  if l:files == ""
    return
  endif

  " Create a new window, move it below the spec and read in a diff.
  botright new
  exe "r!svn diff " . substitute(l:files, "\n", " ", "g")
  setf diff

  " Delete the blank line left above the diff.
  1
  delete
  se nobuflisted
  set buftype=nowrite
  set bufhidden=hide
  setlocal noswapfile
  file [svn diff\]
  " Map q to quit easily.
  noremap <silent> <buffer> q <C-W>q

  " Vim 7.4 really doesn't want us to quit windows from a script.
  try
    au QuitPre * qa!
  catch
  endtry

  " Switch back to the top window.
  wincmd k
endfun

" Expand the command line window so we don't have to press RETURN later.
let s:cmdheight = &cmdheight
se cmdheight=3

" Call and then discard our function.
call SVNcommit()
delfunction SVNcommit

" Restore the command window.
exe "se cmdheight=" . s:cmdheight

" Close the scratch buffer.
if version >= 700
  " Vim 7 lets us close the buffer by number.  The changelist is always in #1.
  au BufWinLeave <buffer=1> qa!
else
  " Prior versions can only do it by name.  Fall back to a temporary file.
  au BufWinLeave /tmp/tmp.*.* qa!
endif