" $Id$ vim: set syntax=vim:
" Define the function we'll use.  It's easier to do this than to faff about 
" trying to run a sequence of normal mode commands.
fun! P4submit()
  " There's no point doing this if the spec is readonly.  That probably means 
  " it's a submitted change.
  if ! &ro
    " Clear the unnamed register.
    let @" = ""
    try
      " Delete the spec blurb if it exists.
      /^# A Perforce Change Spec/,/^$/d
      " If the blurb was deleted the text will be in the unnamed register.
      if @" != ""
        " Allow closing an unmodified spec.
        set nomod

        " Create a new window, move it below the spec and read in a diff.
        botright new
        r!p4 diff
        setf diff

        " Delete the blank line left above the diff.
        1
        delete
        set nobuflisted
        set buftype=nofile
        set bufhidden=hide
        setlocal noswapfile

        " Switch back to the top window and put the cursor by the description.
        wincmd k
        resize 10
        exe "normal G"
        ?<enter description here>
        let @/ = ""
      endif
    catch
      " We get here if no blurb was deleted.  This is the case if we aren't 
      " editing a change.
    endtry
  endif
endfun

" Expand the command line window so we don't have to press RETURN later.
let s:cmdheight = &cmdheight
set cmdheight=2

" Call and then discard our function.
call P4submit()
delfunction P4submit
" Don't expand tabs in the spec.
set noexpandtab

" Restore the command window.
exe "set cmdheight=" . s:cmdheight

" Close the scratch buffer.
if version >= 700
  " Vim 7 lets us close the buffer by number.  The changelist is always in #1.
  au BufWinLeave <buffer=1> qa!
else
  " Prior versions can only do it by name.  Fall back to a temporary file.
  au BufWinLeave /tmp/tmp.*.* qa!
endif