" Mangling for terminal code ripped from desert256.

if version > 580
    " no guarantees for version 5.8 and below, but this makes it stop
    " complaining
    "hi clear
    if exists("syntax_on")
        syntax reset
    endif
endif
let g:colors_name="iain"

if has("gui_running") || &t_Co == 88 || &t_Co == 256
    " functions {{{
    " returns an approximate grey index for the given grey level
    fun! <SID>grey_number(x)
        if &t_Co == 88
            if a:x < 23
                return 0
            elseif a:x < 69
                return 1
            elseif a:x < 103
                return 2
            elseif a:x < 127
                return 3
            elseif a:x < 150
                return 4
            elseif a:x < 173
                return 5
            elseif a:x < 196
                return 6
            elseif a:x < 219
                return 7
            elseif a:x < 243
                return 8
            else
                return 9
            endif
        else
            if a:x < 14
                return 0
            else
                let l:n = (a:x - 8) / 10
                let l:m = (a:x - 8) % 10
                if l:m < 5
                    return l:n
                else
                    return l:n + 1
                endif
            endif
        endif
    endfun

    " returns the actual grey level represented by the grey index
    fun! <SID>grey_level(n)
        if &t_Co == 88
            if a:n == 0
                return 0
            elseif a:n == 1
                return 46
            elseif a:n == 2
                return 92
            elseif a:n == 3
                return 115
            elseif a:n == 4
                return 139
            elseif a:n == 5
                return 162
            elseif a:n == 6
                return 185
            elseif a:n == 7
                return 208
            elseif a:n == 8
                return 231
            else
                return 255
            endif
        else
            if a:n == 0
                return 0
            else
                return 8 + (a:n * 10)
            endif
        endif
    endfun

    " returns the palette index for the given grey index
    fun! <SID>grey_color(n)
        if &t_Co == 88
            if a:n == 0
                return 16
            elseif a:n == 9
                return 79
            else
                return 79 + a:n
            endif
        else
            if a:n == 0
                return 16
            elseif a:n == 25
                return 231
            else
                return 231 + a:n
            endif
        endif
    endfun

    " returns an approximate color index for the given color level
    fun! <SID>rgb_number(x)
        if &t_Co == 88
            if a:x < 69
                return 0
            elseif a:x < 172
                return 1
            elseif a:x < 230
                return 2
            else
                return 3
            endif
        else
            if a:x < 75
                return 0
            else
                let l:n = (a:x - 55) / 40
                let l:m = (a:x - 55) % 40
                if l:m < 20
                    return l:n
                else
                    return l:n + 1
                endif
            endif
        endif
    endfun

    " returns the actual color level for the given color index
    fun! <SID>rgb_level(n)
        if &t_Co == 88
            if a:n == 0
                return 0
            elseif a:n == 1
                return 139
            elseif a:n == 2
                return 205
            else
                return 255
            endif
        else
            if a:n == 0
                return 0
            else
                return 55 + (a:n * 40)
            endif
        endif
    endfun

    " returns the palette index for the given R/G/B color indices
    fun! <SID>rgb_color(x, y, z)
        if &t_Co == 88
            return 16 + (a:x * 16) + (a:y * 4) + a:z
        else
            return 16 + (a:x * 36) + (a:y * 6) + a:z
        endif
    endfun

    " returns the palette index to approximate the given R/G/B color levels
    fun! <SID>color(r, g, b)
        " get the closest grey
        let l:gx = <SID>grey_number(a:r)
        let l:gy = <SID>grey_number(a:g)
        let l:gz = <SID>grey_number(a:b)

        " get the closest color
        let l:x = <SID>rgb_number(a:r)
        let l:y = <SID>rgb_number(a:g)
        let l:z = <SID>rgb_number(a:b)

        if l:gx == l:gy && l:gy == l:gz
            " there are two possibilities
            let l:dgr = <SID>grey_level(l:gx) - a:r
            let l:dgg = <SID>grey_level(l:gy) - a:g
            let l:dgb = <SID>grey_level(l:gz) - a:b
            let l:dgrey = (l:dgr * l:dgr) + (l:dgg * l:dgg) + (l:dgb * l:dgb)
            let l:dr = <SID>rgb_level(l:gx) - a:r
            let l:dg = <SID>rgb_level(l:gy) - a:g
            let l:db = <SID>rgb_level(l:gz) - a:b
            let l:drgb = (l:dr * l:dr) + (l:dg * l:dg) + (l:db * l:db)
            if l:dgrey < l:drgb
                " use the grey
                return <SID>grey_color(l:gx)
            else
                " use the color
                return <SID>rgb_color(l:x, l:y, l:z)
            endif
        else
            " only one possibility
            return <SID>rgb_color(l:x, l:y, l:z)
        endif
    endfun

    " returns the palette index to approximate the 'rrggbb' hex string
    fun! <SID>rgb(rgb)
        let l:r = ("0x" . strpart(a:rgb, 0, 2)) + 0
        let l:g = ("0x" . strpart(a:rgb, 2, 2)) + 0
        let l:b = ("0x" . strpart(a:rgb, 4, 2)) + 0

        return <SID>color(l:r, l:g, l:b)
    endfun

    " sets the highlighting for the given group
    fun! <SID>X(group, fg, bg, attr)
        " Our dark grey ends up being too light when Vim is run inside screen
        " on an 88-colour urxvt.
        let l:hackgrey = "#303030"
        let l:hackterm = "^screen-256color"
        let l:hackbad = 235
        let l:hackgood = 234
        if a:fg != ""
            if a:fg =~ '^#'
                let l:fg = <SID>rgb(substitute(a:fg, '^#', '', ''))
                if a:fg == l:hackgrey && &term =~ l:hackterm && l:fg == l:hackbad
                  let l:fg = l:hackgood
                endif
            else
                let l:fg=a:fg
            endif
            exec "hi " . a:group . " guifg=" . a:fg . " ctermfg=" . l:fg
        endif
        if a:bg != ""
            if a:bg =~ '^#'
                let l:bg = <SID>rgb(substitute(a:bg, '^#', '', ''))
                if a:bg == l:hackgrey && &term =~ l:hackterm && l:bg == l:hackbad
                  let l:bg = l:hackgood
                endif
            else
                let l:bg=a:bg
            endif
            exec "hi " . a:group . " guibg=" . a:bg . " ctermbg=" . l:bg
        endif
        if a:attr != ""
            exec "hi " . a:group . " gui=" . a:attr . " cterm=" . a:attr
        endif
    endfun
    " }}}
    " From darkblue.
    call <SID>X("ErrorMsg", "#ffffff", "#287eff", "")
    call <SID>X("Visual", "#ffffff", "#8080ff", "")
    call <SID>X("VisualNOS", "", "#8080ff", "underline")
    "call <SID>X("Todo", "#d14a14", "#1248d1", "")
    call <SID>X("Search", "#ffffff", "#2050d0", "")
    call <SID>X("IncSearch", "#b0ffff", "#2050d0", "")
    "call <SID>X("SpecialKey", "#00ffff", "", "")
    call <SID>X("Directory", "#008bff", "", "")
    call <SID>X("Title", "#ff00ff", "", "none")
    call <SID>X("WarningMsg", "#ff0000", "", "")
    "call <SID>X("WildMenu", "#ffff00", "#000000", "")
    call <SID>X("ModeMsg", "#22cce2", "", "")
    call <SID>X("Question", "#00ff00", "", "none")
    "call <SID>X("NonText", "#0030ff", "", "")
    call <SID>X("VertSplit", "#000000", "#808080", "none")
    call <SID>X("Folded", "#808080", "#303030", "")
    call <SID>X("FoldColumn", "#808080", "#303030", "")
    call <SID>X("LineNr", "#90f020", "#303030", "")
    call <SID>X("CursorLineNr", "#303030", "#90f020", "none")
    call <SID>X("DiffAdd", "", "#008bff", "")
    call <SID>X("DiffChange", "", "#8b008b", "")
    call <SID>X("DiffDelete", "#008b8b", "#303030", "")
    call <SID>X("DiffText", "#ffffff", "#ff0000", "none")
    call <SID>X("Cursor", "#000000", "#00ff00", "")
    call <SID>X("CursorLine", "", "#2e2e2e", "none")
    call <SID>X("ColorColumn", "", "#2e2e2e", "none")
    call <SID>X("lCursor", "#000000", "#ffffff", "")
    "call <SID>X("Comment", "#80a0ff", "", "")
    "call <SID>X("Constant", "#ffa0a0", "", "")
    "call <SID>X("Special", "#ffa500", "", "")
    "call <SID>X("Identifier", "#40ffff", "", "")
    "call <SID>X("Statement", "#ffff60", "", "none")
    "call <SID>X("PreProc", "#ff80ff", "", "none")
    "call <SID>X("Type", "#60ff60", "", "none")
    call <SID>X("Ignore", "#ffffff", "", "")
    call <SID>X("TabLineFill", "#303030", "#90f020", "")

    " My stuff.
    hi def Normal guifg=#c0c0c0 guibg=#000020

    call <SID>X("StatusLineNC", "black", "#808080", "none")
    call <SID>X("StatusLine", "white", "#000080", "none")
    call <SID>X("User1", "white", "#000080", "bold")
    call <SID>X("WildMenu", "blue", "white", "bold")
    call <SID>X("Todo", "black", "green", "bold")
    call <SID>X("MoreMsg", "#00ff00", "", "none")

    call <SID>X("Repeat", "yellow", "", "none")
    call <SID>X("Label", "#90f020", "", "none")
    call <SID>X("Conditional", "#ffff60", "", "none")
    call <SID>X("Operator", "#e0e000", "", "none")
    call <SID>X("Statement", "#ffff00", "", "none")

    hi! link TabLineSel StatusLine
    hi! link TabLine StatusLineNC

    hi clear CursorLine

    hi MatchParen ctermbg=blue

    call <SID>X("Pmenu", "#ffffff", "#287eff", "")

    hi Comment ctermfg=lightblue cterm=none guifg=#80a0ff gui=none

    call <SID>X("Function", "darkgreen", "", "none")
    call <SID>X("Identifier", "#40ffff", "", "none")

    hi Character ctermfg=darkmagenta cterm=bold guifg=magenta gui=bold
    hi String ctermfg=darkmagenta cterm=none guifg=magenta gui=none
    call <SID>X("Float", "magenta", "", "none")
    call <SID>X("Number", "magenta", "", "bold")
    call <SID>X("Boolean", "darkred", "", "bold")
    call <SID>X("Constant", "darkmagenta", "", "bold")
    hi NonText ctermfg=blue cterm=none guifg=blue gui=none

    call <SID>X("SpecialChar", "#ff0000", "", "none")
    hi SpecialKey ctermfg=blue cterm=none guifg=blue gui=none
    call <SID>X("Special", "#ff0000", "", "none")

    call <SID>X("Include", "red", "", "none")
    call <SID>X("Macro", "red", "", "none")
    call <SID>X("PreCondit", "darkred", "", "none")
    call <SID>X("PreProc", "darkred", "", "bold")

    hi StorageClass ctermfg=green cterm=none guifg=lightgreen gui=none
    hi Structure ctermfg=darkgreen cterm=bold guifg=green gui=bold
    hi Type ctermfg=darkgreen cterm=none guifg=green gui=none

    " Fix up shell stuff. XXX: Should this go in ~/.vim/after/syntax/sh.vim?
    hi link shShellVariables Identifier

    " Fix up Perl stuff.

    " Signs to highlight marks.
    call <SID>X("MarkLine", "", "#303030", "")
    call <SID>X("MarkDot", "red", "#303030", "")
    call <SID>X("MarkSign", "lightblue", "#303030", "")
    call <SID>X("MarkArrow", "#00ff00", "#303030", "")
    hi! link SignColumn LineNr

    " Fix up NERDTree stuff.
    hi link treeExecFile Type
    hi treeLink cterm=none ctermfg=cyan gui=none guifg=cyan
    hi link treeOpenable treeDirSlash
    hi link treeClosable treeDirSlash
    hi link treePart treeDirSlash
    hi link treePartFile treeDirSlash

    " Fix up BufExplorer stuff.
    hi link bufExplorerHelp Include
    hi link bufExplorerSortBy Include
    hi link bufExplorerMapping Identifier
    hi link bufExplorerTitle Statement
    hi link bufExplorerActBuf Directory
    hi link bufExplorerAltBuf Type
    hi link bufExplorerCurBuf Statement
    hi link bufExplorerHidBuf Comment
    hi link bufExplorerUnlBuf String
    hi link bufExplorerBufNbr Normal
endif

" vim: set fdl=0 fdm=marker: