.vimrc

   1 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
   2 " Multi-version vimrc compatible with version 4 and above.
   3 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
   4
   5 " Note that "if <condition> | call Something() | endif" syntax is unsupported
   6 " in Vim 4 so we write all our functions out the long way.  It does work in
   7 " autocommand definitions, however.
   8
   9 " Vim 4 complains if version isn't set in the configuration file.
  10 version 4.0
  11
  12 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
  13 " Handle options safe to use in version 4.  Vim 4 parses but ignores the
  14 " "if version" syntax used later in this file so we don't use it.  No attempt
  15 " is made to make this configuration compatible with Vim 3.
  16 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
  17 " No compatibility mode.
  18 se nocp
  19
  20 " Tabstop 2.
  21 se ts=2
  22 " And use spaces not tabs.
  23 se expandtab
  24 " And << and >> indent by 2.
  25 se sw=2
  26
  27 " Allow backspace to delete before start of line.
  28 se bs=2
  29
  30 " Show the ruler.
  31 se ruler
  32 " Show partial commands in the ruler.
  33 se showcmd
  34 " And always show the status line.
  35 se laststatus=2
  36
  37 " Use C indent style.
  38 se cindent
  39 se cinkeys=0{,0},0),:,!^F,o,O,e
  40 se cinoptions=b1,c2
  41
  42 " GUI options.
  43 se go=aglmr
  44
  45 " Don't be bugged by messages at the bottom of the screen.
  46 se shm=aot
  47
  48 " Find as you type.
  49 se incsearch
  50
  51 " Case-insensitive search.
  52 se ignorecase
  53 " But override by typing capitals.
  54 se smartcase
  55
  56 " Look for ctags in home directory first.
  57 se tags=~/.tags,./tags,tags
  58
  59 " Don't timeout waiting to interpet, eg, <ESC>OA as an escape code.
  60 se ttimeoutlen=100
  61
  62 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
  63 " Handle options only available in Vim 5 and above.
  64 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
  65 if version >= "500"
  66 version 5.0
  67
  68 " Tell Vim we use dark backgrounds in our terminals.
  69 if ! has("gui_running")
  70   se bg=dark
  71 endif
  72
  73 " Enable tab-completion prompting for commands.
  74 se wildmenu
  75 " Don't list object files when globbing files to load.
  76 se wildignore+=*.o,*.obj
  77 " So there's no need to assign them low priority.
  78 se suffixes-=*.o,*.obj
  79
  80 " Save sessions in UNIX format with / as file separator.  This is
  81 " cross-platform.
  82 se ssop+=unix,slash
  83
  84 " Nuke any pre-existing autocommands.
  85 autocmd!
  86
  87 " Save the current window width so we can restore it when we quit.
  88 let oldcols=&columns
  89
  90 " More GUI options.  Add icon, tearoffs and toolbar.
  91 se go+=itT
  92
  93 " Allow dynamic window resize even if we aren't in an xterm.
  94 se t_WS=\e[8;%p1%d;%p2%dt
  95
  96 " Highlight search results.
  97 se hlsearch
  98
  99 " Set graphical window title.
 100 se titlestring=%{Show_TitleString()}
 101
 102 " Syntax highlighting.  New versions will use syn enable instead.
 103 if version < 600
 104   syn on
 105 endif
 106
 107 " Use a discernably different colour to highlight the cursor which shows
 108 " matching brackets.  Our regular cursor is green so use blue instead of cyan.
 109 hi MatchParen ctermbg=blue
 110
 111 " Catch typos.
 112 command! W :w
 113 command! Wq :wq
 114 command! Wqa :wqa
 115
 116 " Set up our variables.
 117 fun! Iain_Vars()
 118   if ! exists("b:iainlist")
 119     let b:iainlist = 0
 120   endif
 121   if ! exists("b:iainhex")
 122     let b:iainhex = 0
 123   endif
 124   if ! exists("b:iainverbose")
 125     let b:iainverbose = 0
 126   endif
 127   if ! exists("b:iainstatus")
 128     " Window Flags: (F)ocused, (I)nsert mode, Cursor (H)old.
 129     let b:iainstatus = "Fih"
 130   endif
 131   if ! exists("g:iainextracolumns")
 132     let g:iainextracolumns = 0
 133   endif
 134 endfun
 135
 136 " Helper for status line.
 137 " Show space, underscore or dollar sign depending on list mode.
 138 fun! Show_List()
 139   call Iain_Vars()
 140   if b:iainlist == 0
 141     " No list.
 142     return " "
 143   elseif b:iainlist == 1
 144     " Just tabs.
 145     return "_"
 146   else
 147     " Full list.
 148     return "\$"
 149   endif
 150 endfun
 151
 152 " Helper for status line.
 153 " Show c or C to denote case-sensitivity.
 154 fun! Show_Case()
 155   if &ic
 156     return "c"
 157   else
 158     return "C"
 159   endif
 160 endfun
 161
 162 " Helper for status line.
 163 " Show the size of the tabstop.
 164 fun! Show_Tabstop()
 165   return &ts
 166 endfun
 167
 168 " Helper for status line.
 169 " Show p when paste mode is on.
 170 fun! Show_Paste()
 171   if &paste
 172     return "p"
 173   else
 174     return ""
 175   endif
 176 endfun
 177
 178 " Show the window title.
 179 fun! Show_TitleString()
 180   if bufname("") == ""
 181     let l:ts1='Vim'
 182   else
 183     let l:ts1=printf("%2d: %s", bufnr(""), expand('%t'))
 184   endif
 185   return printf("%s (%s) %s", l:ts1, getcwd(), v:servername)
 186 endfun
 187
 188 " Show the status line.
 189 fun! Show_StatusLine()
 190   call Iain_Vars()
 191   let l:sl1='%2n\:\ %<%f\ [%{Show_List()}%{Show_Case()}%{Show_Tabstop()}%{Show_Paste()}%Y%M%R]\ %='
 192   let l:sl3='L:%4.6l/%-4.6L\ C:%3.6c\ \|\ %P'
 193   let l:hexformat='%b'
 194   if b:iainhex
 195     let l:hexformat='0\x%02B'
 196   endif
 197   if b:iainverbose
 198     let l:sl2=l:hexformat . '\ \|\ P:%4.6o\ '
 199   else
 200     let l:sl2=''
 201   endif
 202   exec "set statusline=" . l:sl1 . l:sl2 . l:sl3
 203 endfun
 204
 205 " Toggle case-sensitivity.
 206 fun! Invert_Case()
 207   let &ic = ! &ic
 208 endfun
 209
 210 " Grow or shrink the window size.
 211 fun! Resize_Columns(op)
 212   " XXX: This won't work inside screen.
 213   " We should really detect whether it would work rather than assume it won't.
 214   if &term =~ '^screen'
 215     return
 216   endif
 217
 218   " Vim 5 hardcodes the size of numbers column to 8.
 219   if version >= 600
 220     let l:numberwidth = &numberwidth
 221   else
 222     let l:numberwidth = 8
 223   endif
 224
 225   exec "se columns" . a:op . "=" . l:numberwidth
 226 endfun
 227
 228 " Toggle number display.
 229 fun! Number()
 230   call Iain_Vars()
 231   let &number = ! &number
 232
 233   let l:i = 0
 234   let l:num_numbers = 0
 235   while l:i <= winnr("$")
 236     if getwinvar(l:i, "&number") == 1
 237       let l:num_numbers = l:num_numbers + 1
 238     endif
 239     let l:i = l:i + 1
 240   endwhile
 241
 242   if l:num_numbers == 0
 243     let g:iainextracolumns = 0
 244     call Resize_Columns("-")
 245   elseif g:iainextracolumns == 0
 246     let g:iainextracolumns = 1
 247     call Resize_Columns("+")
 248   endif
 249 endfun
 250
 251 " Restore window size.
 252 au VimLeave * if exists("oldcols") | let &columns=oldcols | endif
 253
 254 " Map Makefile mode.
 255 au BufEnter * if &ft == "make" | call MakeMode_map() | endif
 256 au BufLeave * if &ft == "make" | call MakeMode_unmap() | endif
 257
 258 " Entering Make mode.
 259 fun! MakeMode_map()
 260         call Iain_Vars()
 261   let b:iainlist=1
 262   call Cycle_List()
 263   set ts=8
 264   set noexpandtab
 265 endfun
 266
 267 " Leaving Make mode.
 268 fun! MakeMode_unmap()
 269   call Cycle_List()
 270   set ts=2
 271   set expandtab
 272 endfun
 273
 274 " Show the status line for the first time.
 275 call Show_StatusLine()
 276
 277 " Function to create mappings with either a hardcoded \ or <Leader>.
 278 fun! Mapping(keysequence,mapping)
 279   if version < "600"
 280     exec "map \\" . a:keysequence . " " . a:mapping
 281   else
 282     exec "map <Leader>" . a:keysequence . " " . a:mapping
 283   endif
 284 endfun
 285
 286 " Use - and = to create underlines.
 287 call Mapping("-", "yyp:s/./-/g<RETURN>:let @/=''<RETURN>:<RETURN>")
 288 call Mapping("=", "yyp:s/./=/g<RETURN>:let @/=''<RETURN>:<RETURN>")
 289
 290 " Change to ts=2 with \2.
 291 call Mapping("2", ":se ts=2<CR>:<CR>")
 292 " Change to ts=4 with \4.
 293 call Mapping("4", ":se ts=4<CR>:<CR>")
 294 " Change to ts=8 with \8.
 295 call Mapping("8", ":se ts=8<CR>:<CR>")
 296 " Change to ts=16 with \6.
 297 call Mapping("6", ":se ts=16<CR>:<CR>")
 298 " Change to ts=32 with \3.
 299 call Mapping("3", ":se ts=32<CR>:<CR>")
 300 " Toggle paste mode with \p.
 301 call Mapping("p", ":se paste!<CR>:<CR>")
 302 " Swap case-sensitivity with \c.
 303 call Mapping("c", ":call Invert_Case()<CR>:<CR>")
 304 " Change number mode with \n.
 305 call Mapping("n", ":call Number()<CR>:<CR>")
 306 " Expand or shrink window size with \> and \<.
 307 call Mapping(">", ":call Resize_Columns('+')<CR>:<CR>")
 308 call Mapping("<", ":call Resize_Columns('-')<CR>:<CR>")
 309 " Clear search pattern with \/.
 310 call Mapping("/", ":let @/=\"\"<CR>:<CR>")
 311
 312 " Forget the Ex mode mapping.
 313 map Q <NOP>
 314
 315 " Vim tip 99: What's the highlighting group under the cursor?
 316 call Mapping("h", ":echo \"hi<\" . synIDattr(synID(line(\".\"),col(\".\"),1),\"name\") . '> trans<' . synIDattr(synID(line(\".\"),col(\".\"),0),\"name\") . \"> lo<\" . synIDattr(synIDtrans(synID(line(\".\"),col(\".\"),1)),\"name\") . \">\"<CR>")
 317
 318 endif
 319
 320 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
 321 " Handle options only available in Vim 6 and above.
 322 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
 323 if version >= "600"
 324 version 6.0
 325
 326 " Remember quickfix state.
 327 let g:quickfixing=0
 328
 329 " Set indenting by filetype.
 330 filetype indent on
 331
 332 " Less intrusive syntax highlighting.
 333 syn enable
 334
 335 " Nice GUI colour.
 336 if has("gui_running")
 337   se guifont=DejaVu\ Sans\ Mono\ 10
 338   colo darkblue
 339   hi LineNr guibg=#303030
 340 elseif &t_Co > 16
 341   try
 342     colo iain
 343   catch
 344   endtry
 345 endif
 346 if has("win32")
 347   se guifont=DejaVu_Sans_Mono:h10:cANSI
 348 endif
 349
 350 " Ignore whitespace when diffing.
 351 se diffopt=filler,iwhite
 352
 353 " Expand window when doing a vertical diff.
 354 if &diff
 355   let &columns = 164
 356 endif
 357
 358 " Remember that we are opening the quickfix window.
 359 au BufWinEnter quickfix let g:quickfixing=1
 360 au BufUnload * if &ft == "qf" | let g:quickfixing=0 | endif
 361
 362 " Allow in-place editing of crontabs.
 363 au FileType crontab set backupcopy=yes
 364
 365 " Make * and # work the way you expect in visual mode.
 366 vnoremap * y/\V<C-R>=substitute(escape(@@,"/\\"),"\n","\\\\n","ge")<CR><CR>
 367 vnoremap # y?\V<C-R>=substitute(escape(@@,"?\\"),"\n","\\\\n","ge")<CR><CR>
 368
 369 " Change list mode.
 370 fun! Cycle_List()
 371   let basic='tab:\\_,trail:_,extends:<,precedes:>'
 372   call Iain_Vars()
 373   let b:iainlist = b:iainlist + 1
 374   if b:iainlist > 2
 375     let b:iainlist = 0
 376   endif
 377   if b:iainlist == 0
 378     set nolist
 379   elseif b:iainlist == 1
 380     exec "set lcs=" . basic
 381     set list
 382   else
 383     exec "set lcs=" . basic . ",eol:$"
 384     set list
 385   endif
 386 endfun
 387
 388 " Cycle between hex and decimal display of toolbar stuff.
 389 fun! Cycle_HexStatusLine()
 390   call Iain_Vars()
 391   let b:iainhex = ! b:iainhex
 392   call Show_StatusLine()
 393 endfun
 394
 395 " Cycle verbose display of toolbar stuff.
 396 fun! Cycle_VerboseStatusLine()
 397   call Iain_Vars()
 398   let b:iainverbose = ! b:iainverbose
 399   call Show_StatusLine()
 400 endfun
 401
 402 " Toggle quickfix window.
 403 fun! Cycle_Quickfix()
 404   if g:quickfixing == 1
 405     cclose
 406     let g:quickfixing=0
 407   else
 408     copen
 409   endif
 410 endfun
 411
 412 " Swap hex/decimal statusline with \x.
 413 call Mapping("x", ":call Cycle_HexStatusLine()<CR>:<CR>")
 414 " Change statusline verbosity with \v.
 415 call Mapping("v", ":call Cycle_VerboseStatusLine()<CR>:<CR>")
 416 " Cycle list styles with \l.
 417 call Mapping("l", ":call Cycle_List()<CR>:<CR>")
 418 " Toggle tags with \t.
 419 call Mapping("t", ":Tlist<CR>")
 420 " Change foldmethod with \f.
 421 call Mapping("f", ":se foldenable!<CR>:<CR>")
 422 " Toggle quickfix window with \q.
 423 call Mapping("q", ":call Cycle_Quickfix()<CR>:<CR>")
 424 " Rerun filetype detection with \s.  The s is for syntax, as this will be
 425 " updated as a side-effect.
 426 call Mapping("s", ":filetype detect<CR>:<CR>")
 427
 428 " Change status bar colour when various things happen.
 429 fun! Highlight_StatusLine(flag)
 430   " Get current status.
 431   call Iain_Vars()
 432
 433   " Change the status based on the flag.  XXX: Does Vim let us to do flags?
 434   let re = "[" . tolower(a:flag) . toupper(a:flag) . "]"
 435   let b:iainstatus = substitute(b:iainstatus, re, a:flag, "")
 436
 437   " Default colour.
 438   let s:colour = "darkblue"
 439   let s:termcolour = ""
 440   let s:term88colour = "17"
 441   let s:term256colour = "17"
 442   " Maybe override depending on status.
 443   if b:iainstatus =~# "H"
 444     if b:iainstatus =~# "I"
 445       " Held in insert mode.  Add extra highlight if we don't have focus.
 446       if b:iainstatus =~# "f"
 447         let s:colour = "darkred"
 448         let s:term88colour = "32"
 449         let s:term256colour = "88"
 450       else
 451         let s:colour = "darkmagenta"
 452         let s:term88colour = "33"
 453         let s:term256colour = "90"
 454       endif
 455     endif
 456   else
 457     if b:iainstatus =~# "I"
 458       " Regular insert mode.
 459       let s:colour = "darkmagenta"
 460       let s:term88colour = "33"
 461       let s:term256colour = "90"
 462     endif
 463   endif
 464
 465   if &t_Co == 88
 466     let s:termcolour = s:term88colour
 467   elseif &t_Co == 256
 468     let s:termcolour = s:term256colour
 469   else
 470     let s:termcolour = s:colour
 471   endif
 472
 473   exec "highlight StatusLine guifg=white guibg=" . s:colour . " ctermbg=white ctermfg=" . s:termcolour
 474 endfun
 475
 476 call Highlight_StatusLine("")
 477 endif
 478
 479 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
 480 " Handle options only available in Vim 7 and above.
 481 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
 482 if version >= "700"
 483 version 7.0
 484
 485 au CursorHoldI * call Highlight_StatusLine("H")
 486 au CursorMovedI * call Highlight_StatusLine("h")
 487 au FocusGained * call Highlight_StatusLine("F")
 488 au FocusLost * call Highlight_StatusLine("f")
 489 au InsertEnter * call Highlight_StatusLine("I")
 490 au InsertLeave * call Highlight_StatusLine("i")
 491
 492 " Make diffs vertical by default.
 493 se diffopt+=vertical
 494
 495 " Set size of numbers column.
 496 se numberwidth=5
 497
 498 " Add "previous tab" mapping as gb.
 499 map gb :tabPrev<CR>
 500
 501 " Transparency.
 502 if has("gui_macvim")
 503   se transparency=15
 504 endif
 505
 506 " Perforce.
 507 let g:p4EnableMenu=1
 508 let g:p4Presets='P4CONFIG'
 509 endif