.vimrc

   1 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
   2 " Multi-version vimrc compatible with version 4 and above.
   3 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
   4
   5 " Note that "if <condition> | call Something() | endif" syntax is unsupported
   6 " in Vim 4 so we write all our functions out the long way.  It does work in
   7 " autocommand definitions, however.
   8
   9 " Vim 4 complains if version isn't set in the configuration file.
  10 version 4.0
  11
  12 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
  13 " Handle options safe to use in version 4.  Vim 4 parses but ignores the
  14 " "if version" syntax used later in this file so we don't use it.  No attempt
  15 " is made to make this configuration compatible with Vim 3.
  16 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
  17 " No compatibility mode.
  18 se nocp
  19
  20 " Tabstop 2.
  21 se ts=2
  22 " And use spaces not tabs.
  23 se expandtab
  24 " And << and >> indent by 2.
  25 se sw=2
  26
  27 " Allow backspace to delete before start of line.
  28 se bs=2
  29
  30 " Show the ruler.
  31 se ruler
  32 " Show partial commands in the ruler.
  33 se showcmd
  34 " And always show the status line.
  35 se laststatus=2
  36
  37 " Use C indent style.
  38 se cindent
  39 se cinkeys=0{,0},0),:,!^F,o,O,e
  40 se cinoptions=b1,c2
  41
  42 " GUI options.
  43 se go=aglmr
  44
  45 " Don't be bugged by messages at the bottom of the screen.
  46 se shm=aot
  47
  48 " Find as you type.
  49 se incsearch
  50
  51 " Case-insensitive search.
  52 se ignorecase
  53 " But override by typing capitals.
  54 se smartcase
  55
  56 " Look for ctags in home directory first.
  57 se tags=~/.tags,./tags,tags
  58
  59 " Don't timeout waiting to interpet, eg, <ESC>OA as an escape code.
  60 se ttimeoutlen=100
  61
  62 " Use ^B to search backward when completing.
  63 inoremap <C-b> <C-p>
  64 " Use ^L to show matching completions but don't select one.
  65 inoremap <C-l> <C-n><C-p>
  66
  67 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
  68 " Handle options only available in Vim 5 and above.
  69 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
  70 if version >= "500"
  71 version 5.0
  72
  73 " Tell Vim we use dark backgrounds in our terminals.
  74 if ! has("gui_running")
  75   se bg=dark
  76 endif
  77
  78 " Enable tab-completion prompting for commands.
  79 se wildmenu
  80 " Don't list object files when globbing files to load.
  81 se wildignore+=*.o,*.obj
  82 " So there's no need to assign them low priority.
  83 se suffixes-=*.o,*.obj
  84
  85 " Save sessions in UNIX format with / as file separator.  This is
  86 " cross-platform.
  87 se ssop+=unix,slash
  88
  89 " Nuke any pre-existing autocommands.
  90 autocmd!
  91
  92 " Save the current window width so we can restore it when we quit.
  93 let oldcols=&columns
  94
  95 " More GUI options.  Add icon, tearoffs and toolbar.
  96 se go+=itT
  97
  98 " Allow dynamic window resize even if we aren't in an xterm.
  99 se t_WS=\e[8;%p1%d;%p2%dt
 100
 101 " Highlight search results.
 102 se hlsearch
 103
 104 " Set graphical window title.
 105 se titlestring=%{Show_TitleString()}
 106
 107 " Syntax highlighting.  New versions will use syn enable instead.
 108 if version < "600"
 109   syn on
 110 endif
 111
 112 " Use a discernably different colour to highlight the cursor which shows
 113 " matching brackets.  Our regular cursor is green so use blue instead of cyan.
 114 hi MatchParen ctermbg=blue
 115
 116 " Catch typos.
 117 command! W :w
 118 command! Wq :wq
 119 command! Wqa :wqa
 120
 121 " Set up our variables.
 122 fun! Iain_Vars()
 123   if ! exists("b:iainlist")
 124     let b:iainlist = 0
 125   endif
 126   if ! exists("b:iainhex")
 127     let b:iainhex = 0
 128   endif
 129   if ! exists("b:iainverbose")
 130     let b:iainverbose = 0
 131   endif
 132   if ! exists("b:iainstatus")
 133     " Window Flags: (F)ocused, (I)nsert mode, Cursor (H)old.
 134     let b:iainstatus = "Fih"
 135   endif
 136   if ! exists("g:iainextracolumns")
 137     let g:iainextracolumns = 0
 138   endif
 139 endfun
 140
 141 " Helper for status line.
 142 " Show space, underscore or dollar sign depending on list mode.
 143 fun! Show_List()
 144   call Iain_Vars()
 145   if b:iainlist == 0
 146     " No list.
 147     return " "
 148   elseif b:iainlist == 1
 149     " Just tabs.
 150     return "_"
 151   else
 152     " Full list.
 153     return "\$"
 154   endif
 155 endfun
 156
 157 " Helper for status line.
 158 " Show c or C to denote case-sensitivity.
 159 fun! Show_Case()
 160   if &ic
 161     return "c"
 162   else
 163     return "C"
 164   endif
 165 endfun
 166
 167 " Helper for status line.
 168 " Show the size of the tabstop.
 169 fun! Show_Tabstop()
 170   return &ts
 171 endfun
 172
 173 " Helper for status line.
 174 " Show p when paste mode is on.
 175 fun! Show_Paste()
 176   if &paste
 177     return "p"
 178   else
 179     return ""
 180   endif
 181 endfun
 182
 183 " Show the window title.
 184 fun! Show_TitleString()
 185   if bufname("") == ""
 186     let l:ts1='Vim'
 187   else
 188     let l:ts1=printf("%2d: %s", bufnr(""), expand('%t'))
 189   endif
 190   return printf("%s (%s) %s", l:ts1, getcwd(), v:servername)
 191 endfun
 192
 193 " Show the status line.
 194 fun! Show_StatusLine()
 195   call Iain_Vars()
 196   let l:sl1='%2n\:\ %<%f\ [%{Show_List()}%{Show_Case()}%{Show_Tabstop()}%{Show_Paste()}%Y%M%R]\ %='
 197   let l:sl3='L:%4.6l/%-4.6L\ C:%3.6c\ \|\ %P'
 198   let l:hexformat='%b'
 199   if b:iainhex
 200     let l:hexformat='0\x%02B'
 201   endif
 202   if b:iainverbose
 203     let l:sl2=l:hexformat . '\ \|\ P:%4.6o\ '
 204   else
 205     let l:sl2=''
 206   endif
 207   exec "set statusline=" . l:sl1 . l:sl2 . l:sl3
 208 endfun
 209
 210 " Toggle case-sensitivity.
 211 fun! Invert_Case()
 212   let &ic = ! &ic
 213 endfun
 214
 215 " Grow or shrink the window size.
 216 fun! Resize_Columns(op)
 217   " XXX: This won't work inside screen.
 218   " We should really detect whether it would work rather than assume it won't.
 219   if &term =~ '^screen'
 220     return
 221   endif
 222
 223   " Vim 5 hardcodes the size of numbers column to 8.
 224   if version >= "700"
 225     let l:numberwidth = &numberwidth
 226   else
 227     let l:numberwidth = 8
 228   endif
 229
 230   exec "se columns" . a:op . "=" . l:numberwidth
 231 endfun
 232
 233 " Toggle number display.
 234 fun! Number()
 235   call Iain_Vars()
 236   let &number = ! &number
 237
 238   if version >= "700"
 239     let l:i = 0
 240     let l:num_numbers = 0
 241     while l:i <= winnr("$")
 242       if getwinvar(l:i, "&number") == 1
 243         let l:num_numbers = l:num_numbers + 1
 244       endif
 245       let l:i = l:i + 1
 246     endwhile
 247
 248     if l:num_numbers == 0
 249       let g:iainextracolumns = 0
 250       call Resize_Columns("-")
 251     elseif g:iainextracolumns == 0
 252       let g:iainextracolumns = 1
 253       call Resize_Columns("+")
 254     endif
 255   endif
 256 endfun
 257
 258 " Restore window size.
 259 au VimLeave * if exists("oldcols") | let &columns=oldcols | endif
 260
 261 " Map Makefile mode.
 262 au BufEnter * if &ft == "make" | call MakeMode_map() | endif
 263 au BufLeave * if &ft == "make" | call MakeMode_unmap() | endif
 264
 265 " Entering Make mode.
 266 fun! MakeMode_map()
 267         call Iain_Vars()
 268   let b:iainlist=1
 269   call Cycle_List()
 270   set ts=8
 271   set noexpandtab
 272 endfun
 273
 274 " Leaving Make mode.
 275 fun! MakeMode_unmap()
 276   call Cycle_List()
 277   set ts=2
 278   set expandtab
 279 endfun
 280
 281 " Show the status line for the first time.
 282 call Show_StatusLine()
 283
 284 " Function to create mappings with either a hardcoded \ or <Leader>.
 285 fun! Mapping(keysequence,mapping)
 286   if version < "600"
 287     exec "map \\" . a:keysequence . " " . a:mapping
 288   else
 289     exec "map <Leader>" . a:keysequence . " " . a:mapping
 290   endif
 291 endfun
 292
 293 " Use - and = to create underlines.
 294 call Mapping("-", "yyp:s/./-/g<RETURN>:let @/=''<RETURN>:<RETURN>")
 295 call Mapping("=", "yyp:s/./=/g<RETURN>:let @/=''<RETURN>:<RETURN>")
 296
 297 " Change to ts=2 with \2.
 298 call Mapping("2", ":se ts=2<CR>:<CR>")
 299 " Change to ts=4 with \4.
 300 call Mapping("4", ":se ts=4<CR>:<CR>")
 301 " Change to ts=8 with \8.
 302 call Mapping("8", ":se ts=8<CR>:<CR>")
 303 " Change to ts=16 with \6.
 304 call Mapping("6", ":se ts=16<CR>:<CR>")
 305 " Change to ts=32 with \3.
 306 call Mapping("3", ":se ts=32<CR>:<CR>")
 307 " Toggle paste mode with \p.
 308 call Mapping("p", ":se paste!<CR>:<CR>")
 309 " Swap case-sensitivity with \c.
 310 call Mapping("c", ":call Invert_Case()<CR>:<CR>")
 311 " Change number mode with \n.
 312 call Mapping("n", ":call Number()<CR>:<CR>")
 313 " Expand or shrink window size with \> and \<.
 314 call Mapping(">", ":call Resize_Columns('+')<CR>:<CR>")
 315 call Mapping("<", ":call Resize_Columns('-')<CR>:<CR>")
 316 " Clear search pattern with \/.
 317 call Mapping("/", ":let @/=\"\"<CR>:<CR>")
 318
 319 " Forget the Ex mode mapping.
 320 map Q <NOP>
 321
 322 " Vim tip 99: What's the highlighting group under the cursor?
 323 call Mapping("h", ":echo \"hi<\" . synIDattr(synID(line(\".\"),col(\".\"),1),\"name\") . '> trans<' . synIDattr(synID(line(\".\"),col(\".\"),0),\"name\") . \"> lo<\" . synIDattr(synIDtrans(synID(line(\".\"),col(\".\"),1)),\"name\") . \">\"<CR>")
 324
 325 endif
 326
 327 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
 328 " Handle options only available in Vim 6 and above.
 329 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
 330 if version >= "600"
 331 version 6.0
 332
 333 " Remember quickfix state.
 334 let g:quickfixing=0
 335
 336 " Set indenting by filetype.
 337 filetype indent on
 338
 339 " Less intrusive syntax highlighting.
 340 syn enable
 341
 342 " Nice GUI colour.
 343 if has("gui_running")
 344   se guifont=DejaVu\ Sans\ Mono\ 10
 345   colo darkblue
 346   hi LineNr guibg=#303030
 347 elseif &t_Co > 16
 348   try
 349     colo iain
 350   catch
 351   endtry
 352 endif
 353 if has("win32")
 354   se guifont=DejaVu_Sans_Mono:h10:cANSI
 355 endif
 356 hi! link TabLineSel StatusLine
 357 hi! link TabLine StatusLineNC
 358
 359 " Ignore whitespace when diffing.
 360 se diffopt=filler,iwhite
 361
 362 " Expand window when doing a vertical diff.
 363 if &diff
 364   let &columns = 164
 365 endif
 366
 367 " Remember that we are opening the quickfix window.
 368 au BufWinEnter quickfix let g:quickfixing=1
 369 au BufUnload * if &ft == "qf" | let g:quickfixing=0 | endif
 370
 371 " Allow in-place editing of crontabs.
 372 au FileType crontab set backupcopy=yes
 373
 374 " Make * and # work the way you expect in visual mode.
 375 vnoremap * y/\V<C-R>=substitute(escape(@@,"/\\"),"\n","\\\\n","ge")<CR><CR>
 376 vnoremap # y?\V<C-R>=substitute(escape(@@,"?\\"),"\n","\\\\n","ge")<CR><CR>
 377
 378 " Change list mode.
 379 fun! Cycle_List()
 380   let basic='tab:\\_,trail:_,extends:<,precedes:>'
 381   call Iain_Vars()
 382   let b:iainlist = b:iainlist + 1
 383   if b:iainlist > 2
 384     let b:iainlist = 0
 385   endif
 386   if b:iainlist == 0
 387     set nolist
 388   elseif b:iainlist == 1
 389     exec "set lcs=" . basic
 390     set list
 391   else
 392     exec "set lcs=" . basic . ",eol:$"
 393     set list
 394   endif
 395 endfun
 396
 397 " Cycle between hex and decimal display of toolbar stuff.
 398 fun! Cycle_HexStatusLine()
 399   call Iain_Vars()
 400   let b:iainhex = ! b:iainhex
 401   call Show_StatusLine()
 402 endfun
 403
 404 " Cycle verbose display of toolbar stuff.
 405 fun! Cycle_VerboseStatusLine()
 406   call Iain_Vars()
 407   let b:iainverbose = ! b:iainverbose
 408   call Show_StatusLine()
 409 endfun
 410
 411 " Toggle quickfix window.
 412 fun! Cycle_Quickfix()
 413   if g:quickfixing == 1
 414     cclose
 415     let g:quickfixing=0
 416   else
 417     copen
 418   endif
 419 endfun
 420
 421 " Swap hex/decimal statusline with \x.
 422 call Mapping("x", ":call Cycle_HexStatusLine()<CR>:<CR>")
 423 " Change statusline verbosity with \v.
 424 call Mapping("v", ":call Cycle_VerboseStatusLine()<CR>:<CR>")
 425 " Cycle list styles with \l.
 426 call Mapping("l", ":call Cycle_List()<CR>:<CR>")
 427 " Toggle tags with \t.
 428 call Mapping("t", ":Tlist<CR>")
 429 " Change foldmethod with \f.
 430 call Mapping("f", ":se foldenable!<CR>:<CR>")
 431 " Toggle quickfix window with \q.
 432 call Mapping("q", ":call Cycle_Quickfix()<CR>:<CR>")
 433 " Rerun filetype detection with \s.  The s is for syntax, as this will be
 434 " updated as a side-effect.
 435 call Mapping("s", ":filetype detect<CR>:<CR>")
 436
 437 fun! <SID>Iain_Colour(colour)
 438   if &t_Co == 88
 439     if a:colour == "darkblue"
 440       return 17
 441     elseif a:colour == "darkmagenta"
 442       return 33
 443     elseif a:colour == "darkred"
 444       return 32
 445     elseif a:colour == "red"
 446       return 64
 447     endif
 448   elseif &t_Co == 256
 449     if a:colour == "darkblue"
 450       return 17
 451     elseif a:colour == "darkmagenta"
 452       return 90
 453     elseif a:colour == "darkred"
 454       return 88
 455     elseif a:colour == "red"
 456       return 196
 457     endif
 458   else
 459     return a:colour
 460   endif
 461 endfun
 462
 463 " Change status bar colour when various things happen.
 464 " Flags: H/h: Cursor held/moved.
 465 "        F/f: Focus gained/lost.
 466 "        I/i: Insert mode entered/left.
 467 fun! Highlight_StatusLine(flag)
 468   " Get current status.
 469   call Iain_Vars()
 470
 471   " Change the status based on the flag.  XXX: Does Vim let us to do flags?
 472   let re = "[" . tolower(a:flag) . toupper(a:flag) . "]"
 473   let b:iainstatus = substitute(b:iainstatus, re, a:flag, "")
 474
 475   let l:normalcolour = "darkblue"
 476   let l:editingcolour = "darkmagenta"
 477   let l:warningcolour = "darkred"
 478   let l:readonlycolour = "red"
 479
 480   " Default colour.
 481   let l:colour = l:normalcolour
 482   " Maybe override depending on status.
 483   if b:iainstatus =~# "H"
 484     if b:iainstatus =~# "I"
 485       " Held in insert mode.  Add extra highlight if we don't have focus.
 486       if b:iainstatus =~# "f"
 487         let l:colour = l:warningcolour
 488       else
 489         let l:colour = l:editingcolour
 490       endif
 491     endif
 492   else
 493     if b:iainstatus =~# "I"
 494       " Regular insert mode.
 495       let l:colour = l:editingcolour
 496     endif
 497   endif
 498
 499   " Override again if readonly.
 500   if l:colour != l:normalcolour
 501     if getbufvar("", "&ro")
 502       let l:colour = l:readonlycolour
 503     endif
 504   endif
 505
 506   let l:termcolour = <SID>Iain_Colour(l:colour)
 507
 508   exec "highlight StatusLine guifg=white guibg=" . l:colour . " ctermbg=white ctermfg=" . l:termcolour
 509 endfun
 510
 511 call Highlight_StatusLine("")
 512 endif
 513
 514 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
 515 " Handle options only available in Vim 7 and above.
 516 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
 517 if version >= "700"
 518 version 7.0
 519
 520 " Helper to show tab name.
 521 fun! <SID>TabName(label, gui)
 522   let l:label = a:label
 523   if l:label == ""
 524     let l:label = "No Name"
 525     if a:gui
 526       let l:label = "[" . l:label . "]"
 527     endif
 528   else
 529     let l:label = fnamemodify(l:label, ":t")
 530     if strlen(l:label) >= 18
 531       let l:label = l:label[0:17] . ".."
 532     endif
 533   endif
 534   return l:label
 535 endfun
 536
 537 " Find out if any buffer was modified.
 538 fun! <SID>TabModified(buflist)
 539   let l:i = 0
 540   while i < len(a:buflist)
 541     if getbufvar(a:buflist[l:i], "&modified") == 1
 542       return "+"
 543     endif
 544     let l:i = l:i + 1
 545   endwhile
 546   return ""
 547 endfun
 548
 549 " Tab line.
 550 fun! Show_TabLine()
 551   let l:s = "%#TabLineFill#Tabs:"
 552
 553   let l:i = 0
 554   while l:i < tabpagenr("$")
 555     let l:i = l:i + 1
 556     " Get the label.
 557     let l:buflist = tabpagebuflist(l:i)
 558     let l:winnr = tabpagewinnr(l:i)
 559     let l:n = tabpagewinnr(l:i, "$")
 560     let l:label = <SID>TabName(bufname(l:buflist[l:winnr - 1]), 0)
 561     let l:modified = <SID>TabModified(l:buflist)
 562
 563     " Choose highlighting.
 564     if l:i == tabpagenr()
 565       let l:s .= "%#TabLineSel#[" . l:n . l:modified . " " . l:label . "]"
 566     else
 567       let l:s .= "%#TabLine# " . l:n . l:modified . " " . l:label . " "
 568     endif
 569   endwhile
 570
 571   " Padding.
 572   let l:s .= "%#TabLine#%T"
 573   return l:s
 574 endfun
 575
 576 " Per tab label for the GUI.
 577 fun! Show_GUITabLine()
 578   let l:buflist = tabpagebuflist(v:lnum)
 579   let l:winnr = tabpagewinnr(v:lnum)
 580   let l:s = tabpagewinnr(v:lnum, "$")
 581   let l:label = <SID>TabName(bufname(l:buflist[l:winnr - 1]), 1)
 582   let l:modified = <SID>TabModified(l:buflist)
 583
 584   let l:s .= l:modified . " " . l:label
 585   return l:s
 586 endfun
 587
 588 se tabline=%!Show_TabLine()
 589 se guitablabel=%!Show_GUITabLine()
 590
 591 au CursorHoldI * call Highlight_StatusLine("H")
 592 au CursorMovedI * call Highlight_StatusLine("h")
 593 au FocusGained * call Highlight_StatusLine("F")
 594 au FocusLost * call Highlight_StatusLine("f")
 595 au InsertEnter * call Highlight_StatusLine("I")
 596 au InsertLeave * call Highlight_StatusLine("i")
 597
 598 " Limit the size of the popup menu when completing.
 599 se pumheight=20
 600
 601 " Make diffs vertical by default.
 602 se diffopt+=vertical
 603
 604 " Set size of numbers column.
 605 se numberwidth=5
 606
 607 " Add "previous tab" mapping as gb.
 608 map gb :tabprevious<CR>:<CR>
 609
 610 " Transparency.
 611 if has("gui_macvim")
 612   se transparency=15
 613 endif
 614
 615 " Yet more GUI options.  Add tabs.
 616 se go+=e
 617
 618 " Perforce.
 619 let g:p4EnableMenu=1
 620 let g:p4Presets='P4CONFIG'
 621 endif