.vimrc

   1 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
   2 " Multi-version vimrc compatible with version 4 and above.   vim6:set fdm=marker:
   3 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
   4
   5 " Note that "if <condition> | call Something() | endif" syntax is unsupported
   6 " in Vim 4 so we write all our functions out the long way.  It does work in
   7 " autocommand definitions, however.
   8
   9 " Vim 4 complains if version isn't set in the configuration file.
  10 version 4.0
  11
  12 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
  13 " Handle options safe to use in version 4.  Vim 4 parses but ignores the
  14 " "if version" syntax used later in this file so we don't use it.  No attempt
  15 " is made to make this configuration compatible with Vim 3.
  16 " Some of these settings should strictly be wrapped inside "if has()" blocks
  17 " but that would cause them not to be ignored by Vim 4.
  18 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
  19 "{{{1
  20 " No compatibility mode.
  21 se nocp
  22
  23 " Tabstop 2.
  24 se ts=2
  25 " And use spaces not tabs.
  26 se expandtab
  27 " And << and >> indent by 2.
  28 se sw=2
  29 " Backspace deletes full tab width at the start of a line.
  30 se smarttab
  31
  32 " Allow backspace to delete before start of line.
  33 se bs=2
  34
  35 " Don't jump to the start of the line when using H, L etc.
  36 se nosol
  37
  38 " Show the ruler.
  39 se ruler
  40 " Show partial commands in the ruler.
  41 se showcmd
  42 " And always show the status line.
  43 se laststatus=2
  44
  45 " Use C indent style.
  46 se cindent
  47 se cinkeys=0{,0},0),:,!^F,o,O,e
  48 se cinoptions=b1,c2
  49
  50 " GUI options.
  51 se go=aglmr
  52
  53 " Don't be bugged by messages at the bottom of the screen.
  54 se shm=aot
  55
  56 " Find as you type.
  57 se incsearch
  58
  59 " Case-insensitive search.
  60 se ignorecase
  61 " But override by typing capitals.
  62 se smartcase
  63
  64 " Look for ctags in home directory first.
  65 se tags=~/.tags,./tags,tags
  66
  67 " Don't timeout waiting to interpet, eg, <ESC>OA as an escape code.
  68 se ttimeoutlen=100
  69
  70 " Remember undo list for closed (but not wiped) buffers.
  71 se hidden
  72
  73 " Use ^B to search backward when completing.
  74 inoremap <C-b> <C-p>
  75 " Use ^L to show matching completions but don't select one.
  76 inoremap <C-l> <C-n><C-p>
  77
  78 " Swap jump keys.
  79 nnoremap ' `
  80 nnoremap ` '
  81
  82 " Select previous widnow.
  83 nnoremap <C-w>^ <C-w>p
  84 nnoremap <C-w><C-^> <C-w>p
  85 "}}}1
  86
  87 " Find stuff.
  88 if (has("win32") || has("win64")) && version >= "504"
  89   se rtp=~/.vim,$VIMRUNTIME
  90 endif
  91
  92 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
  93 " Handle options only available in Vim 5 and above.
  94 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
  95 if version >= "500" "{{{1
  96 version 5.0
  97
  98 " Tell Vim we use dark backgrounds in our terminals.
  99 if ! has("gui_running")
 100   se bg=dark
 101 endif
 102
 103 " Allow mouse use in a terminal but only if it can work.
 104 if has("xterm_clipboard")
 105   se mouse=nvir
 106 endif
 107
 108 " Update more quickly.  For use with sign highlighting as polling for
 109 " CursorMove makes redrawing slow.
 110 if has("signs")
 111   se updatetime=500
 112 endif
 113
 114 " Enable tab-completion prompting for commands.
 115 if has("wildmenu")
 116   se wildmenu
 117   " Don't list object files when globbing files to load.
 118   se wildignore+=*.o,*.obj
 119   " So there's no need to assign them low priority.
 120   se suffixes-=*.o,*.obj
 121 endif
 122
 123 " Save sessions in UNIX format with / as file separator.  This is
 124 " cross-platform.
 125 if has("mksession")
 126   se ssop+=unix,slash
 127 endif
 128
 129 " How often do we need to use ^A/^X on octals?
 130 se nf=hex
 131
 132 " Nuke any pre-existing autocommands.
 133 if has("autocmd")
 134   augroup Display
 135   autocmd!
 136   augroup Mode
 137   autocmd!
 138   if has("signs")
 139     augroup Signs
 140     autocmd!
 141   endif
 142   augroup StatusLine
 143   autocmd!
 144   augroup File
 145   autocmd!
 146   augroup END
 147 endif
 148
 149 " Save the current window dimensions so we can restore them when we quit.
 150 if ! exists("g:oldcols")
 151   let g:oldcols=&columns
 152 endif
 153 if ! exists("g:oldlines")
 154   let g:oldlines=&lines
 155 endif
 156
 157 " More GUI options.  Add icon and tearoffs.
 158 if has("gui")
 159   se go+=i
 160   se go+=t
 161 endif
 162
 163 " Allow dynamic window resize even if we aren't in an xterm.
 164 se t_WS=\e[8;%p1%d;%p2%dt
 165
 166 " Highlight search results.
 167 if has("extra_search")
 168   se hlsearch
 169 endif
 170
 171 " Syntax highlighting.  New versions will use syn enable instead.
 172 if version < "600"
 173   syn on
 174 endif
 175
 176 if has("user_commands")
 177   " Catch typos.
 178   command! W :w
 179   command! Wq :wq
 180   command! Wqa :wqa
 181 endif
 182
 183 " Forget the Ex mode mapping.
 184 map Q <NOP>
 185
 186 if has("autocmd")
 187   " Position the compview plugin window.
 188   au Display BufEnter -SearchResults- set buftype=nowrite | set nonumber | wincmd J
 189 endif
 190 endif "}}}1
 191
 192 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
 193 " Handle options only available in Vim 5.2 and above.
 194 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
 195 if version >= "502" "{{{1
 196 version 5.2
 197
 198 " Helper to initialise a variable.
 199 fun! Prep_Var(var, value) "{{{2
 200   if exists(a:var)
 201     return
 202   endif
 203   exe "let " . a:var . "=" . a:value
 204 endfun "}}}2
 205
 206 " Set up our variables.
 207 fun! Iain_Vars() "{{{2
 208   call Prep_Var("w:iainlist", 0)
 209   call Prep_Var("b:iainhex", 0)
 210   call Prep_Var("b:iainverbose", 0)
 211   " Window Flags: (F)ocused, (I)nsert mode, Cursor (H)old.
 212   call Prep_Var("b:iainstatus", "'Fih'")
 213   call Prep_Var("g:iainextracolumnsnumber", "''")
 214   call Prep_Var("g:iainextracolumnslist", "''")
 215   call Prep_Var("b:iainalt", 0)
 216   if has("signs")
 217     call Prep_Var("g:marksigns", 0)
 218     call Prep_Var("g:firstsign", 100)
 219   endif
 220   call Prep_Var("g:resizable", "''")
 221 endfun "}}}2
 222
 223 " Show the window title.
 224 fun! Show_TitleString() "{{{2
 225   if bufname("") == ""
 226     let l:ts1='Vim'
 227   else
 228     " Vim 5 doesn't have printf.
 229     let l:ts1=bufnr("")
 230     if l:ts1 < 10
 231       let l:ts1=" " . l:ts1
 232     endif
 233     let l:ts1=l:ts1 . ": " . expand('%t')
 234   endif
 235   let l:ts1=l:ts1 . " (" .  getcwd() . ")"
 236   if has("clientserver")
 237     let l:ts1=l:ts1 . " " . v:servername
 238   endif
 239   return l:ts1
 240 endfun "}}}2
 241
 242 " Toggle case-sensitivity.
 243 fun! Invert_Case() "{{{2
 244   let &ic = ! &ic
 245 endfun "}}}2
 246
 247 " Can we resize this window?
 248 fun! Can_Resize() "{{{2
 249   call Iain_Vars()
 250
 251   if g:resizable == "0" || g:resizable == "1"
 252     return g:resizable
 253   endif
 254
 255   " Do we KNOW we can(not) resize?
 256   if has("gui_running")
 257     let g:resizable = 1
 258   elseif $RESIZABLE == &term
 259     let g:resizable = 1
 260   elseif $RESIZABLE == "0"
 261     let g:resizable = 0
 262   else
 263     " Assume we can.  Allow overriding.
 264     let g:resizable = 1
 265   endif
 266   return g:resizable
 267 endfun "}}}2
 268
 269 " Grow or shrink the window width.
 270 fun! Resize_Columns(op, ...) "{{{2
 271   if a:op == ""
 272     return
 273   endif
 274
 275   if ! Can_Resize()
 276     return
 277   endif
 278
 279   if a:0 == 0
 280     " Vim 5 hardcodes the size of numbers column to 8.
 281     if version >= "700" && has("linebreak")
 282       let l:columns = &numberwidth
 283     else
 284       let l:columns = 8
 285     endif
 286   else
 287     let l:columns = a:1
 288   endif
 289
 290   exe "let l:resize=" . &columns . a:op . l:columns
 291   let l:resize = "se columns=" . l:resize
 292
 293   " HACK: Inside screen there is an extra line for the status bar.  Vim
 294   " manages the resize by sending an escape sequence to set the number of
 295   " lines and number of columns in one action.  To do this it will first query
 296   " the number of lines and then set <same number of lines> by <new number of
 297   " columns>.  Because of the extra line for the status bar this results in
 298   " the real terminal being shrunk by a line.  We ask for the terminal to grow
 299   " by a line so it ends up actually being the same.
 300   if &term =~ '^screen'
 301     let l:resize = l:resize . " lines=" . (&lines + 1)
 302   endif
 303
 304   exe l:resize
 305 endfun "}}}2
 306
 307 " Grow or shrink the window height.
 308 fun! Resize_Lines(op, lines) "{{{2
 309   if a:op == ""
 310     return
 311   endif
 312
 313   if ! Can_Resize()
 314     return
 315   endif
 316
 317   exe "let l:resize=" . &lines . a:op . a:lines
 318   if &term =~ '^screen'
 319     let l:resize = l:resize + 1
 320   endif
 321   let l:resize = "se lines=" . l:resize
 322
 323   exe l:resize
 324 endfun "}}}2
 325
 326 " Set extra columns depending on window status.
 327 fun! Extra_Columns(extra, var, ...) "{{{2
 328   " Vim 6 doesn't have winnr("$").  Determine which windows are open
 329   " ourselves by using :windo to incremement a counter.  As Vim 5
 330   " doesn't have :windo we require Vim 6 for this.
 331   if v:version < "600"
 332     return ""
 333   endif
 334   if ! has("windows")
 335     return ""
 336   endif
 337
 338   " Remember which window we're in.
 339   let l:winnr = winnr()
 340   let l:num_windows = 0
 341   windo let l:num_windows = l:num_windows + 1
 342   " Switch back to the window we were in.
 343   exe l:winnr . "wincmd w"
 344
 345   call Iain_Vars()
 346
 347   if a:0 == 0
 348     let l:condition = ""
 349   else
 350     let l:condition = a:1
 351   endif
 352
 353   let l:n = 0
 354   let l:i = 1
 355   let l:windows = ""
 356   while l:n < l:num_windows
 357     " If window w exists then getwinvar(w, "&modified") will be 0 or 1.
 358     if getwinvar(l:i, "&modified") =~ '^\d'
 359       let l:n = l:n + 1
 360
 361       let l:val = 0
 362       exe "if getwinvar(" . l:i . ", '" . a:var . "') " . l:condition . " | let l:val = 1 | endif"
 363       if l:val
 364         exe "let l:windows = '" . l:windows . ":" . l:i . "'"
 365       endif
 366     endif
 367     let l:i = l:i + 1
 368   endwhile
 369
 370   let l:extra = "g:iainextracolumns" . a:extra
 371   exe "let l:val = " . l:extra
 372   exe "let " . l:extra . " = '" . l:windows . "'"
 373
 374   if l:windows == l:val
 375     return ""
 376   endif
 377
 378   if l:windows == ""
 379     return "-"
 380   elseif l:val == ""
 381     return "+"
 382   endif
 383 endfun "}}}2
 384
 385 " Toggle number display.
 386 fun! Number(resize) "{{{2
 387   call Iain_Vars()
 388   let &number = ! &number
 389
 390   " Ensure we keep track of any extra columns even if we aren't resizing.
 391   " This prevents confusion when number is set at startup.
 392   let l:extra = Extra_Columns("number", "&number")
 393
 394   if a:resize
 395     call Resize_Columns(l:extra)
 396   endif
 397 endfun "}}}2
 398
 399 " Restore window size.
 400 if has("autocmd") && ! has("gui_running")
 401   au Display VimLeave * if exists("g:oldcols") | call Resize_Columns("-", (&columns - g:oldcols)) | endif
 402   au Display VimLeave * if exists("g:oldlines") | call Resize_Lines("-", (&lines - g:oldlines)) | endif
 403 endif
 404
 405 " Map Makefile mode.
 406 if has("autocmd")
 407   au Mode BufEnter * if &ft == "make" | call MakeMode_map() | endif
 408   au Mode BufLeave * if &ft == "make" | call MakeMode_unmap() | endif
 409 endif
 410
 411 " Entering Make mode.
 412 fun! MakeMode_map() "{{{2
 413   call Iain_Vars()
 414   let w:iainlist=1
 415   call Cycle_List()
 416   set ts=8
 417   set noexpandtab
 418 endfun "}}}2
 419
 420 " Leaving Make mode.
 421 fun! MakeMode_unmap() "{{{2
 422   call Cycle_List()
 423   set ts=2
 424   set expandtab
 425 endfun "}}}2
 426
 427 " Function to create mappings with either a hardcoded \ or <Leader>.
 428 fun! Mapping(keysequence, mapping, ...) "{{{2
 429   if version < "600"
 430     let l:args = "\\" . a:keysequence . " " . a:mapping . ":<CR>"
 431   else
 432     let l:args = "<silent> <Leader>" . a:keysequence . " " . a:mapping
 433   endif
 434   if a:0 == 0
 435     " General mapping.
 436     exec "map " . l:args
 437   else
 438     " Specific mapping(s).
 439     let l:i = 1
 440     while l:i <= a:0
 441       exec "let l:map = a:" . l:i . " . \"map\""
 442       exec l:map . " " . l:args
 443       let l:i = l:i + 1
 444     endwhile
 445   endif
 446 endfun "}}}2
 447
 448 " Use - and = to create underlines.
 449 call Mapping("-", "yyp:s/./-/g<CR>:let @/=''<CR>")
 450 call Mapping("=", "yyp:s/./=/g<CR>:let @/=''<CR>")
 451
 452 fun! Tab_Width(width) "{{{2
 453   exec "set sw=" . a:width
 454   exec "set ts=" . a:width
 455 endfun "}}}2
 456
 457 " Set 2-column tabs with \2.
 458 call Mapping("2", ":call Tab_Width(2)<CR>")
 459 " Set 4-column tabs with \4.
 460 call Mapping("4", ":call Tab_Width(4)<CR>")
 461 " Set 8-column tabs with \8.
 462 call Mapping("8", ":call Tab_Width(8)<CR>")
 463 " Set 16-column tabs with \6.
 464 call Mapping("6", ":call Tab_Width(16)<CR>")
 465 " Set 32-column tabs with \3.
 466 call Mapping("3", ":call Tab_Width(32)<CR>")
 467 " Toggle paste mode with \p.
 468 call Mapping("p", ":se paste!<CR>")
 469 " Swap case-sensitivity with \c.
 470 call Mapping("C", ":call Invert_Case()<CR>")
 471 " Change number mode with \n.
 472 call Mapping("n", ":call Number(1)<CR>")
 473 " Expand or shrink window size with \> and \<.
 474 call Mapping(">", ":call Resize_Columns('+')<CR>")
 475 call Mapping("<", ":call Resize_Columns('-')<CR>")
 476 " Clear search pattern with \/.
 477 call Mapping("/", ":let @/=\"\"<CR>")
 478 " Toggle alternate buffer name with \#.
 479 call Mapping("#", ":call Cycle_Alt()<CR>")
 480
 481 " Set graphical window title.
 482 if has("win32") || has("win64")
 483   " Windows taskbar entries are probably too small to show full titles.
 484   se titlestring=%t
 485 else
 486   se titlestring=%{Show_TitleString()}
 487 endif
 488
 489 " Vim tip 99: What's the highlighting group under the cursor?
 490 call Mapping("h", ":echo \"hi<\" . synIDattr(synID(line(\".\"),col(\".\"),1),\"name\") . '> trans<' . synIDattr(synID(line(\".\"),col(\".\"),0),\"name\") . \"> lo<\" . synIDattr(synIDtrans(synID(line(\".\"),col(\".\"),1)),\"name\") . \">\"<CR>")
 491
 492 fun! Uncluttered_Buffer() "{{{2
 493   if exists("uncluttered_buffer")
 494     if uncluttered_buffer == 1
 495       return 1
 496     endif
 497   endif
 498
 499   if version >= "600"
 500     if &buftype != ''
 501       return 1
 502     endif
 503   endif
 504
 505   if &ft == 'perforce'
 506     return 1
 507   endif
 508
 509   if &ft == 'svn'
 510     return 1
 511   endif
 512
 513   if &ft == 'gitcommit'
 514     return 1
 515   endif
 516
 517   return 0
 518 endfun "}}}2
 519
 520 fun! Startup_Resize() "{{{2
 521   let l:columns = 0
 522
 523   " Resize for numbers.
 524   if &number
 525     if version >= "700" && has("linebreak")
 526       let l:columns = &numberwidth
 527     else
 528       let l:columns = 8
 529     endif
 530   endif
 531
 532   " Resize for signs.
 533   if has("signs")
 534     if g:marksigns
 535       if version >= "600"
 536         let l:columns = l:columns + 2
 537       endif
 538     endif
 539   endif
 540
 541   if g:oldcols < (80 + l:columns)
 542     call Resize_Columns("+", l:columns)
 543   endif
 544 endfun "}}}2
 545
 546 " Change status bar colour when various things happen.
 547 " Flags: H/h: Cursor held/moved.
 548 "        F/f: Focus gained/lost.
 549 "        I/i: Insert mode entered/left.
 550 fun! Highlight_StatusLine(flag) "{{{2
 551   if ! has("statusline")
 552     return
 553   endif
 554   " Get current status.
 555   call Iain_Vars()
 556
 557   " Change the status based on the flag.  XXX: Does Vim let us to do flags?
 558   let l:ic = &ic
 559   set ic
 560   let b:iainstatus = substitute(b:iainstatus, a:flag, a:flag, "")
 561   let &ic = l:ic
 562
 563   let l:normalcolour = "darkblue"
 564   let l:editingcolour = "darkmagenta"
 565   let l:replacecolour = "purple"
 566   let l:warningcolour = "darkred"
 567   let l:readonlycolour = "red"
 568
 569   if b:iainstatus =~# "I"
 570     if v:insertmode == "r"
 571       let l:editingcolour = l:replacecolour
 572     endif
 573   endif
 574
 575   " Default colour.
 576   let l:colour = l:normalcolour
 577   " Maybe override depending on status.
 578   if b:iainstatus =~# "H"
 579     if b:iainstatus =~# "I"
 580       " Held in insert mode.  Add extra highlight if we don't have focus.
 581       if b:iainstatus =~# "f"
 582         let l:colour = l:warningcolour
 583       else
 584         let l:colour = l:editingcolour
 585       endif
 586     endif
 587   else
 588     if b:iainstatus =~# "I"
 589       " Regular insert mode.
 590       let l:colour = l:editingcolour
 591     endif
 592   endif
 593
 594   " Override again if readonly.
 595   if l:colour != l:normalcolour
 596     if getbufvar("", "&ro")
 597       let l:colour = l:readonlycolour
 598     endif
 599   endif
 600
 601   let l:termcolour = Iain_Colour(l:colour)
 602
 603   exec "highlight StatusLine gui=none term=none cterm=none guifg=white guibg=" . l:colour . " ctermfg=white ctermbg=" . l:termcolour
 604   exec "highlight User1 gui=bold term=bold cterm=bold guifg=white guibg=" . l:colour . " ctermfg=white ctermbg=" . l:termcolour
 605 endfun "}}}2
 606
 607 fun! Iain_Colour(colour) "{{{2
 608   if &t_Co == 88
 609     if a:colour == "darkblue"
 610       return 17
 611     elseif a:colour == "darkmagenta"
 612       return 33
 613     elseif a:colour == "purple"
 614       return 35
 615     elseif a:colour == "darkred"
 616       return 32
 617     elseif a:colour == "red"
 618       return 64
 619     endif
 620   elseif &t_Co == 256
 621     if a:colour == "darkblue"
 622       return 17
 623     elseif a:colour == "darkmagenta"
 624       return 90
 625     elseif a:colour == "purple"
 626       return 57
 627     elseif a:colour == "darkred"
 628       return 88
 629     elseif a:colour == "red"
 630       return 196
 631     endif
 632   else
 633     " Colours which cterm*g doesn't recognise.
 634     if a:colour == "purple"
 635       return "magenta"
 636     endif
 637     return a:colour
 638   endif
 639 endfun "}}}2
 640
 641 if has("autocmd")
 642   au StatusLine VimEnter * call Highlight_StatusLine("")
 643
 644   " Show numbers by default.
 645   au Display VimEnter * if ! Uncluttered_Buffer() | call Number(0) | endif
 646 endif
 647 endif "}}}1
 648
 649 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
 650 " Handle options only available in Vim 5.4 and above.
 651 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
 652 if version >= "504" "{{{1
 653 version 5.4
 654
 655 " Reuse windows when using sbuffer.
 656 se switchbuf=useopen
 657
 658 " Vim 5 requires a 'n setting for viminfo.
 659 if ! &viminfo
 660   se viminfo='100
 661 endif
 662
 663 " Allow persistent variable saving for localvimrc.
 664 se viminfo+=!
 665
 666 " Do we have Unicode?
 667 fun! Has_Unicode() "{{{2
 668   if ! has('multi_byte')
 669     return 0
 670   endif
 671
 672   if version < "602"
 673     return 0
 674   endif
 675
 676   if &tenc =~? '^u\(tf\|cs\)'
 677     return 1
 678   endif
 679
 680   if ! strlen(&tenc) && &enc =~? '^u\(tf\|cs\)'
 681     return 1
 682   endif
 683
 684   return 0
 685 endfun "}}}2
 686
 687 " Helper for status line.
 688 " Show file encoding
 689 fun! Show_Encoding() "{{{2
 690   if version < "600"
 691     return ""
 692   endif
 693
 694   let l:enc = &fenc
 695   let l:symbol = ""
 696   if l:enc == ""
 697     let l:enc = &enc
 698     if l:enc == ""
 699       return ""
 700     endif
 701     if bufname("%") == ""
 702       if Has_Unicode()
 703         let l:symbol = '•'
 704       else
 705         let l:symbol = '*'
 706       endif
 707     endif
 708   endif
 709
 710   if has("multi_byte")
 711     if &bomb
 712       if Has_Unicode()
 713         let l:symbol = "☻"
 714       else
 715         let l:symbol = "@"
 716       endif
 717     endif
 718   endif
 719
 720   " Don't return anything if the encoding is utf-8.
 721   if l:enc == "utf-8"
 722     if l:symbol == ""
 723       return ""
 724     endif
 725   endif
 726
 727   return l:symbol . l:enc . ","
 728 endfun "}}}2
 729
 730 " Helper for status line.
 731 " Show space, underscore or dollar sign depending on list mode.
 732 fun! Show_List() "{{{2
 733   call Iain_Vars()
 734   if w:iainlist == 0
 735     " No list.
 736     return ""
 737   elseif Has_Unicode()
 738     if w:iainlist == 1
 739       " Just tabs.
 740       return "»"
 741     else
 742       " Full list.
 743       return "¶"
 744     endif
 745   else
 746     if w:iainlist == 1
 747       return "_"
 748     else
 749       return "\$"
 750     endif
 751   endif
 752 endfun "}}}2
 753
 754 " Helper for status line.
 755 " Show c or C to denote case-sensitivity.
 756 fun! Show_Case() "{{{2
 757   if &ic
 758     return "c"
 759   else
 760     return "C"
 761   endif
 762 endfun "}}}2
 763
 764 " Helper for status line.
 765 " Mark DOS buffers.
 766 fun! Show_DOS() "{{{2
 767   if &ff == "unix"
 768     return ""
 769   endif
 770   return &ff . ","
 771 endfun "}}}2
 772
 773 " Helper for status line.
 774 " Show the size of the tabstop.
 775 fun! Show_Tabstop() "{{{2
 776   return &ts
 777 endfun "}}}2
 778
 779 " Helper for status line.
 780 " Show p when paste mode is on.
 781 fun! Show_Paste() "{{{2
 782   if &paste
 783     return "p"
 784   else
 785     return ""
 786   endif
 787 endfun "}}}2
 788
 789 " Helper for status line.
 790 " Show v when virtualedit mode is block, insert or onemore.
 791 " Show V when virtualedit mode is all.
 792 fun! Show_VirtualEdit() "{{{2
 793   if ! has("virtualedit")
 794     return ""
 795   endif
 796
 797   if &ve == "all"
 798     return "V"
 799   elseif &ve != ''
 800     return "v"
 801   else
 802     return ""
 803   endif
 804 endfun "}}}2
 805
 806 " Helper for status line.
 807 " Show U when persistent undo is on.
 808 " Show u when persistent undo is off but an undofile exists.
 809 fun! Show_Undo() "{{{2
 810   if ! exists("&undofile")
 811     return ""
 812   endif
 813
 814   if &undofile
 815     return "U"
 816   elseif filereadable(undofile(expand("%")))
 817     return "u"
 818   else
 819     return ""
 820   endif
 821 endfun "}}}2
 822
 823 " Helper for status line.
 824 " Show alternate buffer number and name.
 825 fun! Show_Alt() "{{{2
 826   let l:alt = bufnr("#")
 827   if l:alt < 0 || l:alt == bufnr("") || ! b:iainalt
 828     return ""
 829   endif
 830
 831   return " " . l:alt . ": " . expand("#:t")
 832 endfun "}}}2
 833
 834 " Helper for status line.
 835 " Show scrollbind or cursorbind.
 836 fun! Show_Bind() "{{{2
 837   if has("cursorbind")
 838     if &cursorbind
 839       if Has_Unicode()
 840         return "⇄"
 841       else
 842         return ">"
 843       endif
 844     elseif &scrollbind
 845       if Has_Unicode()
 846         return "⇅"
 847       else
 848         return "^"
 849       endif
 850     endif
 851   endif
 852   return ""
 853 endfun "}}}2
 854
 855 " Helper for status line.
 856 " Show marker if searchforward is unset.
 857 fun! Show_SearchForward() "{{{2
 858   if version >= "702"
 859     if ! v:searchforward
 860       if Has_Unicode()
 861         return "∆"
 862       else
 863         return "^"
 864       endif
 865     endif
 866   endif
 867   return ""
 868 endfun "}}}2
 869
 870 " Helper for status line.
 871 " Show marks set in cursor line.
 872 fun! Show_Marks() "{{{2
 873   if ! exists("g:iainsigns")
 874     return ""
 875   endif
 876
 877   let l:marks = ""
 878
 879   let l:signs = g:iainsigns
 880   let l:sign = ""
 881   let l:cursorline = line(".")
 882   while strlen(l:signs)
 883     let l:sign = matchstr(l:signs, '^[A-Za-z]\+\(:.\)*[.=>-][^ ]\+')
 884     let l:sign = substitute(l:sign, '^[A-Za-z]\+', "", "")
 885     let l:ascii = matchstr(l:sign, '^:.')
 886     let l:mark = substitute(l:sign, '^\(:.\)*[.=>-]', "", "")
 887     if strlen(l:ascii)
 888       let l:ascii = substitute(l:ascii, '^:', "", "")
 889     else
 890       let l:ascii = l:mark
 891     endif
 892     let l:ascii = substitute(l:ascii, '"', '\\"', "")
 893
 894     if l:ascii == "o"
 895       let l:line = "."
 896     else
 897       let l:line = "'" . l:ascii
 898     endif
 899
 900     " Ignore cursor line which will always match.
 901     if l:line != "."
 902       if l:cursorline == line(l:line)
 903         let l:marks = l:marks . l:mark
 904       endif
 905     endif
 906
 907     let l:signs = substitute(l:signs, '^[^ ]\+ *', "", "")
 908   endwhile
 909
 910   if l:marks == ""
 911     return ""
 912   else
 913     return "M:" . l:marks . " "
 914   endif
 915 endfun "}}}2
 916
 917 " Helper for status lines.
 918 " Show Space plugin command.
 919 fun! Show_Space() "{{{2
 920   if exists("*GetSpaceMovement")
 921     let l:ret = GetSpaceMovement()
 922     if l:ret != ""
 923       if Has_Unicode()
 924         let l:ret = "␠" . l:ret . Show_SearchForward()
 925       else
 926         let l:ret "[" . l:ret . Show_SearchForward() . "]"
 927     endif
 928     return l:ret
 929   else
 930     return Show_SearchForward()
 931 endfun "}}}2
 932
 933 " Show the status line.
 934 fun! Show_StatusLine() "{{{2
 935   if ! has("statusline")
 936     return
 937   endif
 938   call Iain_Vars()
 939
 940   " User{N} highlights %{N}*.
 941   " Named highlight groups %#group% aren't available until Vim 7.
 942   let l:normal = '%0*'
 943   let l:bold = '%1*'
 944
 945   " sl1 contains left-aligned stuff.
 946   " sl2 contains stuff shown only when verbose mode is enabled.
 947   " sl3 contains right-aligned stuff.
 948   let l:sl1='%2n\:\ %<' . l:bold . '%f' . l:normal . '\ [%{Show_Encoding()}%{Show_DOS()}%{Show_List()}%{Show_Bind()}%{Show_Case()}%{Show_Tabstop()}%{Show_Paste()}%{Show_VirtualEdit()}%{Show_Undo()}%Y%M%R%{Show_Space()}]%{Show_Alt()}\ '
 949   let l:sl3='%{Show_Marks()}L:' . l:bold . '%4.6l' . l:normal . '/%-4.6L\ C:' . l:bold . '%3.6c%V' . l:normal . '\ \|\ %P'
 950   let l:hexformat='%b'
 951   if b:iainhex
 952     let l:hexformat='0\x%02B'
 953   endif
 954   if b:iainverbose
 955     let l:sl1=l:sl1 . v:version . '\ %='
 956     let l:sl2=l:hexformat . '\ \|\ P:%4.6o\ '
 957   else
 958     let l:sl1=l:sl1 . '%='
 959     let l:sl2=''
 960   endif
 961   exec "set statusline=" . l:sl1 . l:sl2 . l:sl3
 962 endfun "}}}2
 963
 964 " Show the status line for the first time.
 965 call Show_StatusLine()
 966 endif "}}}1
 967
 968 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
 969 " Handle options only available in Vim 6 and above.
 970 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
 971 if version >= "600" "{{{1
 972 version 6.0
 973
 974 if has("win32") || has("win64")
 975   se encoding=utf-8
 976 endif
 977
 978 " Remember quickfix state.
 979 if has("quickfix")
 980   let g:quickfixing=0
 981 endif
 982
 983 " Set indenting by filetype.
 984 filetype indent on
 985
 986 " Less intrusive syntax highlighting.
 987 if has("syntax")
 988   " The :syntax enable command tries to source the syntax.vim runtime script.
 989   " Parsing this .vimrc will fail if for some reason the runtime doesn't
 990   " exist, as could be the case if the binary was installed with no support
 991   " files.  GNU On Windows is one example of an incomplete installation.
 992   try
 993     syn enable
 994   catch
 995   endtry
 996 endif
 997
 998 " Set colours.
 999 if has("gui_running")
1000   if has("win32") || has("win64")
1001     exe "silent se guifont=DejaVu_Sans_Mono:h10:cANSI"
1002   else
1003     exe "silent se guifont=DejaVu\\ Sans\\ Mono\\ 10"
1004   endif
1005 endif
1006 if has("gui_running") || &t_Co > 16
1007   exe "silent colo iain"
1008 endif
1009
1010 " Ignore whitespace when diffing.
1011 if has("diff")
1012   se diffopt=filler,iwhite
1013 endif
1014
1015 if has("autocmd")
1016   if has("quickfix")
1017     " Remember that we are opening the quickfix window.
1018     au Mode BufWinEnter quickfix let g:quickfixing=1
1019     au Mode BufUnload * if &ft == "qf" | let g:quickfixing=0 | endif
1020   endif
1021
1022   " Allow in-place editing of crontabs.
1023   au Mode FileType crontab set backupcopy=yes
1024 endif
1025
1026 " Make * and # work the way you expect in visual mode.
1027 vnoremap * y/\V<C-R>=substitute(escape(@@,"/\\"),"\n","\\\\n","ge")<CR><CR>
1028 vnoremap # y?\V<C-R>=substitute(escape(@@,"?\\"),"\n","\\\\n","ge")<CR><CR>
1029
1030 " Set mark and update highlighting.
1031 if has("signs")
1032   au Signs BufReadPost * call <SID>Highlight_Signs()
1033   au Signs CursorHold * call <SID>Highlight_Signs()
1034 endif
1035
1036 " Helper to set buffer variable for a given sign.
1037 fun! <SID>Prep_Sign(sign) "{{{2
1038   if ! exists("b:sign" . a:sign) || ! g:marksigns
1039     exe "let b:sign" . a:sign . "=0"
1040    endif
1041 endfun "}}}2
1042
1043 fun! <SID>Place_Sign(number, line, old, name) "{{{2
1044   if a:line == a:old
1045     return a:old
1046   endif
1047
1048   exe "sign unplace " . (g:firstsign + a:number) . " buffer=" . bufnr("")
1049   " Don't place the sign if it would conflict with the last change sign.
1050   exe "sign place " . (g:firstsign + a:number) . " line=" . a:line . " name=" . a:name . " buffer=" . bufnr("")
1051   return a:line
1052 endfun "}}}2
1053
1054 fun! <SID>Highlight_Signs(...) "{{{2
1055   if ! has("signs") || ! g:marksigns || Uncluttered_Buffer()
1056     return
1057   endif
1058
1059   let l:signs = g:iainsigns
1060   let l:sign = ""
1061   let l:i = 0
1062   while strlen(l:signs)
1063     let l:sign = matchstr(l:signs, '^[A-Za-z]\+\(:.\)*[.=>-][^ ]\+')
1064
1065     let l:name = substitute(l:sign, '[:.=>-].*', "", "")
1066     let l:var = tolower(l:name)
1067     let l:sign = substitute(l:sign, '^[A-Za-z]\+', "", "")
1068     let l:ascii = matchstr(l:sign, '^:.')
1069     let l:mark = substitute(l:sign, '^\(:.\)*[.=>-]', "", "")
1070     if strlen(l:ascii)
1071       let l:ascii = substitute(l:ascii, '^:', "", "")
1072     else
1073       let l:ascii = l:mark
1074     endif
1075     let l:ascii = substitute(l:ascii, '"', '\\"', "")
1076
1077     if l:ascii == "o"
1078       let l:line = "."
1079     else
1080       let l:line = "'" . l:ascii
1081     endif
1082
1083     call <SID>Prep_Sign(l:var)
1084     exe "let " . l:var . " = <SID>Place_Sign(" . l:i . ", line(\"" . l:line . "\"), b:sign" . l:var . ", \"Mark" . l:name . "\")"
1085     let l:i = l:i + 1
1086
1087     let l:signs = substitute(l:signs, '^[^ ]\+ *', "", "")
1088   endwhile
1089 endfun "}}}2
1090
1091 " Toggle signs.
1092 fun! <SID>Cycle_Signs(resize) "{{{2
1093   if ! has("signs")
1094     return
1095   endif
1096   call Iain_Vars()
1097   let g:marksigns = ! g:marksigns
1098
1099   " Retrofit arrays on to Vim 6.
1100   if ! exists("g:iainsigns")
1101     " Signs are defined in g:iainsigns.  The syntax is as follows:
1102     "
1103     " Sign ::= Name (':' Mark)* Type Symbol
1104     " Type ::= '=' | '-' | '.'
1105     "
1106     " Signs with Type '=' will be highlighted with the MarkSign group.
1107     " Signs with Type '-' will be highlighted with the MarkLine group.
1108     " Signs with Type '.' will be highlighted with the MarkDot group.
1109     " Signs with Type '>' will be highlighted with the MarkArrow group.
1110     " Define the Mark where Symbol is not also the mark name, eg "']".
1111     let g:iainsigns = "Less=< Greater=> Left=( Right=) SquareLeft=[ SquareRight=] BraceLeft={ BraceRight=} a-a b-b c-c d-d e-e f-f A-A B-B C-C D-D E-E F-F"
1112     if Has_Unicode()
1113       let g:iainsigns = g:iainsigns . " Quote:\"=” Dash:'=’ Caret:^.ʌ Dot:..•"
1114       if version < "704"
1115         let g:iainsigns = g:iainsigns ." Cursor:o>▶"
1116       endif
1117     else
1118       let g:iainsigns = g:iainsigns . " Quote=\" Dash=' Caret.^ Dot:..*"
1119       if version < "704"
1120         let g:iainsigns = g:iainsigns ." Cursor>o"
1121       endif
1122     endif
1123   endif
1124
1125   if g:marksigns
1126     " Signs to highlight marks.
1127     " Syntax won't work properly in Vim 6.
1128     let l:signs = g:iainsigns
1129     let l:sign = ""
1130     while strlen(l:signs)
1131       let l:sign = matchstr(l:signs, '^[A-Za-z]\+\(:.\)*[.=>-][^ ]\+')
1132
1133       let l:name = substitute(l:sign, '[:.=>-].*', "", "")
1134       let l:sign = substitute(l:sign, '^[A-Za-z]\+', "", "")
1135       let l:ascii = matchstr(l:sign, '^:.')
1136       let l:mark = substitute(l:sign, '^\(:.\)*[.=>-]', "", "")
1137       if strlen(l:ascii)
1138         let l:ascii = substitute(l:ascii, '^:', "", "")
1139         let l:ascii = matchstr(l:ascii, '^.')
1140       else
1141         let l:ascii = l:mark
1142       endif
1143       let l:ascii = substitute(l:ascii, '"', '\\"', "")
1144       let l:type = substitute(l:sign, '^:.', "", "")
1145       let l:type = matchstr(l:type, '^.')
1146
1147       let l:hl = ""
1148       if l:type == "="
1149         let l:hl = "texthl=MarkSign text="
1150       elseif l:type == "."
1151         let l:hl = "texthl=MarkDot text="
1152       elseif l:type == "-"
1153         let l:hl = "texthl=MarkLine text="
1154       elseif l:type == ">"
1155         let l:hl = "texthl=MarkArrow text="
1156       endif
1157
1158       exe "sign define Mark" . l:name . " " . l:hl . l:mark
1159
1160       let l:signs = substitute(l:signs, '^[^ ]\+ *', "", "")
1161     endwhile
1162
1163     if a:resize
1164       call Resize_Columns("+", 2)
1165     endif
1166     call <SID>Highlight_Signs()
1167   else
1168     let l:i = 0
1169     while l:i < 25
1170       exe "sign unplace " . (g:firstsign + l:i)
1171       let l:i = l:i + 1
1172     endwhile
1173
1174     let l:signs = g:iainsigns
1175     let l:sign = ""
1176     while strlen(l:signs)
1177       let l:sign = matchstr(l:signs, '^[A-Za-z]\+')
1178
1179       exe "sign undefine Mark" . l:sign
1180       call <SID>Prep_Sign(tolower(l:sign))
1181       let l:signs = substitute(l:signs, '^[^ ]\+ *', "", "")
1182     endwhile
1183
1184     if a:resize
1185       call Resize_Columns("-", 2)
1186     endif
1187   endif
1188 endfun "}}}2
1189
1190 " Change list mode.
1191 fun! Cycle_List() "{{{2
1192   " Pretty UTF-8 listchars.
1193   if Has_Unicode()
1194     let basic='tab:»·,trail:…,extends:«,precedes:»'
1195     let eol='eol:¶'
1196     if version >= "700"
1197       let basic=basic . ',nbsp:•'
1198     endif
1199   else
1200     let basic='tab:\\_,trail:_,extends:<,precedes:>'
1201     let eol='eol:$'
1202     if version >= "700"
1203       let basic=basic . ',nbsp:+'
1204     endif
1205   endif
1206   call Iain_Vars()
1207   let w:iainlist = w:iainlist + 1
1208   if w:iainlist > 2
1209     let w:iainlist = 0
1210   endif
1211   if w:iainlist == 0
1212     setlocal nolist
1213   elseif w:iainlist == 1
1214     exec "setlocal lcs=" . basic
1215     setlocal list
1216   else
1217     exec "setlocal lcs=" . basic . "," . eol
1218     setlocal list
1219   endif
1220
1221   call Resize_Columns(Extra_Columns("list", "iainlist", " == 2"), 1)
1222   call Extra_Whitespace_Match()
1223 endfun "}}}2
1224
1225 " Cycle between hex and decimal display of toolbar stuff.
1226 fun! Cycle_HexStatusLine() "{{{2
1227   call Iain_Vars()
1228   let b:iainhex = ! b:iainhex
1229   call Show_StatusLine()
1230 endfun "}}}2
1231
1232 " Cycle verbose display of toolbar stuff.
1233 fun! Cycle_VerboseStatusLine() "{{{2
1234   call Iain_Vars()
1235   let b:iainverbose = ! b:iainverbose
1236   call Show_StatusLine()
1237 endfun "}}}2
1238
1239 " Toggle quickfix window.
1240 fun! Cycle_Quickfix() "{{{2
1241   if ! has("quickfix")
1242     return
1243   endif
1244   if g:quickfixing == 1
1245     cclose
1246     let g:quickfixing=0
1247   else
1248     copen
1249   endif
1250 endfun "}}}2
1251
1252 " Toggle showing alternate buffer information.
1253 fun! Cycle_Alt() "{{{2
1254   call Iain_Vars()
1255   let b:iainalt = ! b:iainalt
1256   call Show_StatusLine()
1257 endfun "{{{2
1258
1259 " To be overridden later if applicable.
1260 fun! Extra_Whitespace_Match() "{{{2
1261   " NOP.
1262 endfun "}}}2
1263
1264 " Swap hex/decimal statusline with \x.
1265 call Mapping("x", ":call Cycle_HexStatusLine()<CR>")
1266 " Change statusline verbosity with \v.
1267 call Mapping("V", ":call Cycle_VerboseStatusLine()<CR>")
1268 " Cycle list styles with \l.
1269 call Mapping("l", ":call Cycle_List()<CR>")
1270 " Toggle tags with \t.
1271 call Mapping("t", ":Tlist<CR>")
1272 " Change foldmethod with \f.
1273 call Mapping("f", ":se foldenable!<CR>")
1274 " Toggle quickfix window with \q.
1275 call Mapping("q", ":call Cycle_Quickfix()<CR>")
1276 " Rerun filetype detection with \s.  The s is for syntax, as this will be
1277 " updated as a side-effect.
1278 call Mapping("S", ":filetype detect<CR>")
1279 " Toggle marks with \m.
1280 call Mapping("m", ":call <SID>Cycle_Signs(1)<CR>")
1281
1282 if has("autocmd")
1283   " Show signs by default.
1284   au Display VimEnter * call <SID>Cycle_Signs(0)
1285 endif
1286
1287 " move.
1288 nmap <A-u> <Plug>MoveLineHalfPageUp
1289 nmap <A-d> <Plug>MoveLineHalfPageDown
1290 vmap <A-u> <Plug>MoveBlockHalfPageUp
1291 vmap <A-d> <Plug>MoveBlockHalfPageDown
1292 endif "}}}1
1293
1294 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
1295 " Handle options only available in Vim 7 and above.
1296 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
1297 if version >= "700" "{{{1
1298 version 7.0
1299
1300 " Narrow buffer with \w.
1301 call Mapping("w", ":NarrowRegion<CR>", "n", "v")
1302 " Narrow window with \W.
1303 call Mapping("W", ":NarrowWindow<CR>", "n", "v")
1304
1305 " Helper to show tab name.
1306 fun! <SID>TabName(label, gui) "{{{2
1307   let l:label = a:label
1308   if l:label == ""
1309     let l:label = "No Name"
1310     if a:gui
1311       let l:label = "[" . l:label . "]"
1312     endif
1313   else
1314     let l:label = fnamemodify(l:label, ":t")
1315     if strlen(l:label) >= 18
1316       let l:label = l:label[0:17] . ".."
1317     endif
1318   endif
1319   return l:label
1320 endfun "}}}2
1321
1322 " Find out if any buffer was modified.
1323 fun! <SID>TabModified(buflist) "{{{2
1324   let l:i = 0
1325   while l:i < len(a:buflist)
1326     if getbufvar(a:buflist[l:i], "&modified") == 1
1327       return "+"
1328     endif
1329     let l:i = l:i + 1
1330   endwhile
1331   return ""
1332 endfun "}}}2
1333
1334 " Tab line.
1335 fun! Show_TabLine() "{{{2
1336   let l:s = "%#TabLineFill#Tabs:"
1337
1338   let l:i = 0
1339   while l:i < tabpagenr("$")
1340     let l:i = l:i + 1
1341     " Get the label.
1342     let l:buflist = tabpagebuflist(l:i)
1343     let l:winnr = tabpagewinnr(l:i)
1344     let l:n = tabpagewinnr(l:i, "$")
1345     let l:label = <SID>TabName(bufname(l:buflist[l:winnr - 1]), 0)
1346     let l:modified = <SID>TabModified(l:buflist)
1347
1348     " Choose highlighting.
1349     if l:i == tabpagenr()
1350       let l:s .= "%#TabLineSel#[" . l:n . l:modified . " " . l:label . "]"
1351     else
1352       let l:s .= "%#TabLine# " . l:n . l:modified . " " . l:label . " "
1353     endif
1354   endwhile
1355
1356   " Padding.
1357   let l:s .= "%#TabLine#%T"
1358   return l:s
1359 endfun "}}}2
1360
1361 " Per tab label for the GUI.
1362 fun! Show_GUITabLine() "{{{2
1363   let l:buflist = tabpagebuflist(v:lnum)
1364   let l:winnr = tabpagewinnr(v:lnum)
1365   let l:s = tabpagewinnr(v:lnum, "$")
1366   let l:label = <SID>TabName(bufname(l:buflist[l:winnr - 1]), 1)
1367   let l:modified = <SID>TabModified(l:buflist)
1368
1369   let l:s .= l:modified . " " . l:label
1370   return l:s
1371 endfun "}}}2
1372
1373 " Handle searching in a BufExplorer window.
1374 fun! <SID>BufExplorer_Search(n) "{{{2
1375   if a:n == 0
1376     let l:re = '^  *\d %'
1377   else
1378     let l:re = "^ *" . a:n
1379   endif
1380
1381   " Find matching line.
1382   let l:line = search(l:re, 'w')
1383   if ! l:line
1384     return
1385   endif
1386
1387   if a:n == 0
1388     return
1389   endif
1390
1391   " Peek ahead to the next matching line.
1392   let l:next = search(l:re, 'w')
1393
1394   " Select the buffer if the match is unambiguous.
1395   if l:next == l:line
1396     exe "normal \<CR>"
1397     return
1398   endif
1399
1400   " Go back.
1401   call cursor(l:line, 0)
1402 endfun! "}}}2
1403
1404 " Entering a BufExplorer window.
1405 fun! <SID>BufExplorer_Map() "{{{2
1406   for l:n in [ "0", "1", "2", "3", "4", "5", "6", "7", "8", "9" ]
1407     exec "nnoremap <buffer> <silent>" . l:n . " :call <SID>BufExplorer_Search(" . l:n . ")<CR>"
1408   endfor
1409 endfun "}}}2
1410
1411 if has("windows")
1412   se tabline=%!Show_TabLine()
1413   se guitablabel=%!Show_GUITabLine()
1414 endif
1415
1416 if has("autocmd")
1417   au StatusLine CursorHoldI * call Highlight_StatusLine("H")
1418   au StatusLine CursorMovedI * call Highlight_StatusLine("h")
1419   au StatusLine FocusGained * call Highlight_StatusLine("F")
1420   au StatusLine FocusLost * call Highlight_StatusLine("f")
1421   au StatusLine InsertEnter * call Highlight_StatusLine("I")
1422   au StatusLine InsertChange * call Highlight_StatusLine("I")
1423   au StatusLine InsertLeave * call Highlight_StatusLine("i")
1424
1425   if has("signs")
1426     au Signs CursorHoldI * call <SID>Highlight_Signs()
1427     au Signs InsertEnter * call <SID>Highlight_Signs()
1428     au Signs InsertLeave * call <SID>Highlight_Signs()
1429   endif
1430
1431   au Mode BufEnter \[BufExplorer\] call <SID>BufExplorer_Map()
1432 endif
1433
1434 " Limit the size of the popup menu when completing.
1435 if has("insert_expand")
1436   se pumheight=20
1437 endif
1438
1439 " Make diffs vertical by default.
1440 if has("diff")
1441   se diffopt+=vertical
1442 endif
1443
1444 " Set size of numbers column.
1445 if has("linebreak")
1446   se numberwidth=5
1447 endif
1448
1449 " Add "previous tab" mapping as gb.
1450 map gb :tabprevious<CR>:<CR>
1451
1452 " Transparency.
1453 if has("gui_macvim")
1454   se transparency=15
1455 endif
1456
1457 " Yet more GUI options.  Add tabs.
1458 if has("gui")
1459   se go+=e
1460 endif
1461
1462 " Perforce.
1463 let g:p4EnableMenu=1
1464 let g:p4Presets='P4CONFIG'
1465
1466 " BufExplorer.
1467 let g:bufExplorerShowRelativePath=1
1468 let g:bufExplorerSplitOutPathName=0
1469
1470 " NERDcommenter.
1471 let g:NERDSpaceDelims=1
1472
1473 " localvimrc.
1474 let g:localvimrc_persistent=1
1475
1476 " Gitv.
1477 let g:Gitv_OpenHorizontal='auto'
1478 let g:Gitv_WipeAllOnClose=1
1479 endif "}}}1
1480
1481 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
1482 " Handle options only available in Vim 7.2 and above.
1483 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
1484 if version >= "702" "{{{1
1485 if has("autocmd")
1486   " http://vim.wikia.com/wiki/Highlight_unwanted_spaces
1487   augroup WhitespaceMatch
1488   autocmd!
1489   au Display BufWinEnter * call Extra_Whitespace_Match()
1490   au Display Syntax * call Extra_Whitespace_Match()
1491   au Display BufWinLeave * call clearmatches()
1492   augroup END
1493
1494   fun! Extra_Whitespace_Match() "{{{2
1495     " \s\+            <whitespace>
1496     "            $    <before end of line>
1497     "        \@<!     <unless preceded by>
1498     "     \%#         <cursor position, ie when typing>
1499     let l:pattern = '\s\+\%#\@<!$'
1500     " Don't match single space in first column of diff.
1501     if &ft =~# '^diff$\|git'
1502       "         \@!  <unless also matching>
1503       " \(^\s$\)     <a single whitespace>
1504       let l:pattern = '\(^\s$\)\@!' . l:pattern
1505     endif
1506
1507     let l:hl = 'ctermfg=red guifg=red'
1508     if ! &list
1509       " Underline if we aren't using listchars.
1510       let l:hl = l:hl . ' cterm=underline gui=underline'
1511     endif
1512     highlight clear ExtraWhitespace
1513     exe "highlight ExtraWhitespace " . l:hl
1514     if exists('w:whitespace_match_number')
1515       try
1516         call matchdelete(w:whitespace_match_number)
1517       catch
1518       endtry
1519       call matchadd('ExtraWhitespace', l:pattern, 10, w:whitespace_match_number)
1520     else
1521       let w:whitespace_match_number = matchadd('ExtraWhitespace', l:pattern)
1522     endif
1523   endfun "}}}2
1524
1525   call Extra_Whitespace_Match()
1526 endif
1527
1528 endif "}}}1
1529
1530 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
1531 " Handle options only available in Vim 7.3 and above.
1532 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
1533 if version >= "703" "{{{1
1534 version 7.3
1535
1536 " Toggle persistent undo with \u.
1537 call Mapping("u", ":call <SID>Cycle_Undo()<CR>")
1538 " Remove persistent undo file with \U.
1539 call Mapping("U", ":call <SID>Clear_Undo()<CR>")
1540
1541 " Toggle gundo window with \g.
1542 call Mapping("g", ":call gundo#GundoToggle()<CR>")
1543
1544 " Use a persistent undo file if it exists.
1545 fun! <SID>Check_Undo() "{{{2
1546   if filereadable(undofile(expand("%")))
1547     setlocal undofile
1548   endif
1549 endfun "}}}2
1550
1551 " Toggle persistent undo for this buffer.
1552 fun! <SID>Cycle_Undo() "{{{2
1553   if has("persistent_undo")
1554     let &undofile = ! &undofile
1555   endif
1556 endfun "}}}2
1557
1558 " Remove the persistent undo file for this buffer.
1559 fun! <SID>Clear_Undo() "{{{2
1560   if ! has("persistent_undo")
1561     return
1562   endif
1563
1564   setlocal noundofile
1565
1566   let l:f = expand("%")
1567   if l:f == ""
1568     return
1569   endif
1570
1571   let l:u = undofile(l:f)
1572   if l:u == ""
1573     return
1574   endif
1575
1576   if ! filereadable(l:u) || ! filewritable(l:u)
1577     return
1578   endif
1579
1580   call delete(l:u)
1581 endfun "}}}2
1582
1583 " Toggle ColorColumn at cursor position.
1584 fun! <SID>Cycle_ColorColumn() "{{{2
1585   if ! has("syntax")
1586     return
1587   endif
1588
1589   let l:cc = &colorcolumn
1590   let l:column = col(".")
1591   let l:re = ",*\\<" . l:column . "\\>"
1592   if l:cc =~# l:re
1593     let l:cc = substitute(l:cc, l:re, "", "g")
1594   else
1595     let l:cc = l:cc . "," . l:column
1596   endif
1597   let &colorcolumn = substitute(l:cc, "^,*", "", "")
1598 endfun "}}}2
1599
1600 if has("syntax")
1601   " Enable showing ColorColumn at cursor position with \CC.
1602   call Mapping("CC", ":call <SID>Cycle_ColorColumn()<CR>")
1603   " Remove last shown ColorColumn with \Cc.
1604   call Mapping("Cc", ":let &colorcolumn=substitute(&colorcolumn, \",*[0-9]*$\", \"\", \"\")<CR>")
1605   " Remove all ColorColumns with \Cx.
1606   call Mapping("Cx", ":se colorcolumn=<CR>")
1607 endif
1608
1609 " Use persistent undo if available.
1610 if has("autocmd")
1611   if has("persistent_undo")
1612     au File BufReadPost * call <SID>Check_Undo()
1613   endif
1614
1615   if has("cursorbind")
1616     au Display WinEnter * if &diff | se cursorbind | endif
1617   endif
1618 endif
1619
1620 " Mapping to reload the gundo window.
1621 if has("autocmd")
1622   au Mode BufEnter * if &ft == "gundo" | try | nnoremap <silent> <buffer> <unique> r :call gundo#GundoToggle()<CR>:call gundo#GundoToggle()<CR> | catch | endtry | endif
1623 endif
1624
1625 endif "}}}1
1626 "
1627 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
1628 " Handle options only available in Vim 7.4 and above.
1629 """"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
1630 if version >= "704" "{{{1
1631 version 7.4
1632
1633 if has("syntax")
1634   se cursorline
1635 endif
1636
1637 endif "}}}1
1638
1639 " Resize after startup.
1640 if version >= "500" "{{{1
1641 if has("autocmd")
1642   au Display VimEnter * call Startup_Resize()
1643 endif
1644 endif "}}}1